Logs lib: change height of the logs panel

[pschiffe]

Hello, is it possible in current setup to change the height of the logs panel? Examples don't show it, and I cannot make it work.

If it's not possible, could the height / dimensions be set via variable?

[v-zhuravlev]

Hi! You can do it as with example in README:

local g = import 'github.com/grafana/grafonnet/gen/grafonnet-latest/main.libsonnet';
local logslib = import 'github.com/grafana/jsonnet-libs/logs-lib/logs/main.libsonnet';


local linuxFilterSelector = 'unit!=""';
local linuxLabels = ['job', 'instance', 'unit', 'level'];

// pick one of Loki's parsers to use: i.e. logfmt, json.
// | __error__=`` is appended automatically
// https://grafana.com/docs/loki/latest/logql/log_queries/#parser-expression
// set null or do not provide at all if parsing is not required.
local formatParser = 'unpack';

// 2. create and export systemd logs dashboard
local systemdLogs =
  logslib.new('Linux systemd logs',
                    datasourceRegex='',
                    filterSelector=linuxFilterSelector,
                    labels=linuxLabels,
                    formatParser=formatParser,
                    showLogsVolume=true)
  // override panels or variables using grafonnet
  {
    panels+:
      {
        logs+:
          g.panel.logs.options.withEnableLogDetails(false),
      },
    variables+:
      {
        regex_search+:
          g.dashboard.variable.textbox.new('regex_search', default='error'),
      },
  };
// export logs dashboard
systemdLogs.dashboards.logs

here you can modify panel height:

        logs+:
          g.panel.logs.options.withEnableLogDetails(false) 
          + { gridPos+: {h: 100} }

[pschiffe]

Hi @v-zhuravlev! Thank you for the reply. It doesn't seem to be picked up:

    // 2. create and export systemd logs dashboard
    'systemd.json':
      logslib.new('Linux systemd logs',
        datasourceRegex='',
        filterSelector=linuxFilterSelector,
        labels=linuxLabels,
        formatParser=formatParser,
        logsVolumeGroupBy=logsVolumeGroupBy,
        extraFilters=extraFilters)
      {
        dashboards+:
          {
            logs+:
              g.dashboard.withTimezone("browser") +
              g.dashboard.time.withFrom(value="now-1h"),
          },
        panels+:
          {
            logs+:
              g.panel.logs.options.withEnableLogDetails(false)
              + { gridPos+: {h: 100} }
          },
      }.dashboards.logs,

The created dashboard still has:

            "gridPos": {
               "h": 18,
               "w": 24,
               "x": 0,
               "y": 18
            },

[pschiffe]

@v-zhuravlev do you know what could be the problem here?

[v-zhuravlev]

you are right. It is not supported that way, sorry for the confusion. Height is enforced on the dashboard layer after panels are created. I'll update it.

[v-zhuravlev]

can you try the latest version and try again?

[pschiffe]

awesome, this works now. thank you!

    'systemd.json':
      logslib.new('Linux systemd logs',
        datasourceRegex='',
        filterSelector=linuxFilterSelector,
        labels=linuxLabels,
        formatParser=formatParser,
        logsVolumeGroupBy=logsVolumeGroupBy,
        extraFilters=extraFilters)
      {
        dashboards+:
          {
            logs+:
              g.dashboard.withTimezone("browser") +
              g.dashboard.time.withFrom(value="now-1h"),
          },
        panels+:
          {
            logs+:
              g.panel.logs.gridPos.withH(36)
          },
      }.dashboards.logs,