WiFi101OTA not working with ConnectionHandler

[brentbrooks70]

Just added WiFiConnectionHandler to code that previously used WiFi101 for MKR1000 board but now the WiFiOTA does not register the board in the ports selection. If I remove ConnectionHandler and revert back to WiFI101 natively (I know ConnectionHandler just calls this library after testing for ARCH of hardware) it works normally. This does not make any sense, any help would be greatly appreciated.

#include <Arduino_WiFiConnectionHandler.h>
#include <WiFi101OTA.h>

const char* ssid = "_SSID_";
const char* password = "_PASSWORD_";

WiFiConnectionHandler net(ssid, password);

void onNetworkConnect(void *_arg) {Serial.println(">>>> CONNECTED to network");}
void onNetworkDisconnect(void *_arg) {Serial.println(">>>> DISCONNECTED from network");}

void setup() 
{
  delay(5000);
  Serial.begin(115200);
  setDebugMessageLevel(2);
  net.addConnectCallback(onNetworkConnect);
  net.addDisconnectCallback(onNetworkDisconnect);
  WiFiOTA.begin("_HostName_", "_Password_", InternalStorage);
}

void loop() 
{
  net.update();
  WiFiOTA.poll();
}

VERSION INFO
MKR1000 Firmware v19.6.1
Arduino IDE v1.8.9
Arduino SAMD (32-bits ARM Cortex-M0+) v1.8.3
WiFi101OTA v1.0.2
Arduino_ConnectionHandler v0.1.3

[brentbrooks70]

Setting setDebugMessageLevel(4); does not seem to provide much additional info, at least not for this issue.

[brentbrooks70]

Okay, by adding a bool OTA_Configured and removing the WiFIOTA.Begin from setup and moving it to loop and performing a check that the WiFi is connected prior to starting the OTA, and not allowing the WiFIOTA.Poll() to run until OTA_Configured has been marked true it is registring itself in the port selection again

#include <Arduino_WiFiConnectionHandler.h>
#include <WiFi101OTA.h>

const char* ssid = "SSID";
const char* password = "PASSWORD";

WiFiConnectionHandler net(ssid, password);

void onNetworkConnect(void *_arg) {Serial.println(">>>> CONNECTED to network");}
void onNetworkDisconnect(void *_arg) {Serial.println(">>>> DISCONNECTED from network");}

bool OTA_Configured = false;

void setup()
{
  delay(5000);
  setDebugMessageLevel(2);
  net.addConnectCallback(onNetworkConnect);
  net.addDisconnectCallback(onNetworkDisconnect);
}

void loop()
{
  net.update();
    if (WiFi.status() == 3 && !OTA_Configured)
    {
      WiFiOTA.begin("HostName", "Password", InternalStorage);
      OTA_Configured = true;
    }
    if (OTA_Configured)
    {
      WiFiOTA.poll();
    }
}

So, it would appear that the WiFi was not connected before trying to start the OTA process, previously my WiFi101 setup was a blocking function and the CnnectionHandler is non-blocking so the OTA just needed some time for the network to connect before initializing.

[ubidefeo]

nice find, @brentbrooks70
I'm happy you figured out some of the inner workings of Arduino_ConnectionHandler.
It implements a state machine that runs on update and handles all conneciton/disconnection/reconnection.
It's still in its first implementation and we're on the lookout for issues as we go.

one interesting thing which might help your case is registering for an onConnect callback.
This way once it connects it can do the WiFiOTA begin and you don't have to poll for its state.

whilst you're at it think about implementing an onDisconnect callback so that you can kill your WiFIOTA and not incur into issues.

If the callback mechanism is not clear let me know and I'll give you some pointers, but in the example it's implemented pretty clearly :)

[brentbrooks70]

@ubidefeo
Duh, of course, use the builtin function instead of checking myself. Think it was too late last night for me to see this obvious answer.
I moved
WiFiOTA.begin("HostName", "Password", InternalStorage);
from loop() and added it to
void onNetworkConnect(void *_arg) { Serial.println(">>>> CONNECTED to network"); WiFiOTA.begin("HostName", "Password", InternalStorage); }
but without checking the state of OTA_Configured it tries to run WiFIOTA.poll(); before it has been initialized and randomly prevents the port selection registration from working. So, checking that a WiFiOTA.begin() has been run prior to issuing a WiFOTA.poll() is still required for stable use. Am I missing or overlooking something again?

You also mentioned

whilst you're at it think about implementing an onDisconnect callback so that you can kill your WiFIOTA and not incur into issues.

According to WiFi101OTA documentation there is only a begin and a poll functionality, how would one go about "killing" it?

Thanks for the reply and assistance!!

[brentbrooks70]

So I have ended up with this as a decent workaround for the moment:

void onNetworkConnect(void *_arg) 
{
  Serial.println(">>>> CONNECTED to network");
  WiFiOTA.begin("HostName", "Password", InternalStorage);
  OTA_Configured = true;
}

void onNetworkDisconnect(void *_arg) 
{
  Serial.println(">>>> DISCONNECTED from network");
  OTA_Configured = false;
}

void loop() 
{
  net.update();
  if (OTA_Configured)
  {
    WiFiOTA.poll();
  }
}

So if WiFI gets disconnected it is not trying to poll something that is not accessible until it reconnects and tries a begin again...Have not tried to disconnect WiFi while running to see if issuing an additional WiFIOTA.begin causes any problems but I will give that a try later tonight by rebooting my wireless router (something I would surely be shot for if I did it whilst the teenagers were home and awake).

Again, @ubidefeo, thanks for your assistance and I will report back later with my reconnection discovery.

[ubidefeo]

what I meant was not polling OTA, but you figured that out.
Also in the begin of ConnectionHandler you have an additional flag for keepAlive which defaults to true and automatically reconnects but you might want to manually re-issue a connection in some cases.
best of luck :)

[brentbrooks70]

I was able to drop my WiFi numerous times and the reconnection to WiFi and OTA worked without any issue that I could detect. Thanks for the tip on the keepAlive, I can see where that could come in handy.

I would consider this issue resolved to my satisfaction but will leave open for now unless you wish to close it @ubidefeo

[ubidefeo]

I think this could help others but does not qualify as an issue.
Let's close it and it'll still be searchable anyway :)

[brentbrooks70]

closed