condition and decondition using traits from #286

Project.toml

@@ -5,6 +5,7 @@ version = "0.13.0"
 [deps]
 AbstractMCMC = "80f14c24-f653-4e6a-9b94-39d6b0f70001"
 AbstractPPL = "7a57a42e-76ec-4ea3-a279-07e840d6d9cf"
+BangBang = "198e06fe-97b7-11e9-32a5-e1d131e6ad66"
 Bijectors = "76274a88-744f-5084-9051-94815aaf08c4"
 ChainRulesCore = "d360d2e6-b24c-11e9-a2a3-2a2ae2dbcce4"
 Distributions = "31c24e10-a181-5473-b8eb-7969acd0382f"
@@ -15,6 +16,7 @@ ZygoteRules = "700de1a5-db45-46bc-99cf-38207098b444"
 [compat]
 AbstractMCMC = "2, 3.0"
 AbstractPPL = "0.2"
+BangBang = "0.3"
 Bijectors = "0.5.2, 0.6, 0.7, 0.8, 0.9"
 ChainRulesCore = "0.9.7, 0.10"
 Distributions = "0.23.8, 0.24, 0.25"

src/DynamicPPL.jl

@@ -9,6 +9,7 @@ using AbstractMCMC: AbstractMCMC
 using ChainRulesCore: ChainRulesCore
 using MacroTools: MacroTools
 using ZygoteRules: ZygoteRules
+using BangBang: BangBang
 
 using Random: Random
 
@@ -67,6 +68,7 @@ export AbstractVarInfo,
     vectorize,
     # Model
     Model,
+    ContextualModel,
     getmissings,
     getargnames,
     generated_quantities,
@@ -81,6 +83,7 @@ export AbstractVarInfo,
     PriorContext,
     MiniBatchContext,
     PrefixContext,
+    ConditionContext,
     assume,
     dot_assume,
     observe,
@@ -99,6 +102,8 @@ export AbstractVarInfo,
     logprior,
     logjoint,
     pointwise_loglikelihoods,
+    condition,
+    decondition,
     # Convenience macros
     @addlogprob!,
     @submodel

src/compiler.jl

@@ -20,19 +20,64 @@ function isassumption(expr::Union{Symbol,Expr})
 
     return quote
         let $vn = $(varname(expr))
-            # This branch should compile nicely in all cases except for partial missing data
-            # For example, when `expr` is `:(x[i])` and `x isa Vector{Union{Missing, Float64}}`
-            if !$(DynamicPPL.inargnames)($vn, __model__) ||
-               $(DynamicPPL.inmissings)($vn, __model__)
-                true
+            if $(DynamicPPL.contextual_isassumption)(__context__, $vn)
+                # Considered an assumption by `__context__` which means either:
+                # 1. We hit the default implementation, e.g. using `DefaultContext`,
+                #    which in turn means that we haven't considered if it's one of
+                #    the model arguments, hence we need to check this.
+                # 2. We are working with a `ConditionContext` _and_ it's NOT in the model arguments,
+                #    i.e. we're trying to condition one of the latent variables.
+                #    In this case, the below will return `true` since the first branch
+                #    will be hit.
+                # 3. We are working with a `ConditionContext` _and_ it's in the model arguments,
+                #    i.e. we're trying to override the value. This is currently NOT supported.
+                #    TODO: Support by adding context to model, and use `model.args`
+                #    as the default conditioning. Then we no longer need to check `inargnames`
+                #    since it will all be handled by `contextual_isassumption`.
+                if !($(DynamicPPL.inargnames)($vn, __model__)) ||
+                   $(DynamicPPL.inmissings)($vn, __model__)
+                    true
+                else
+                    $expr === missing
+                end
             else
-                # Evaluate the LHS
-                $(maybe_view(expr)) === missing
+                false
             end
         end
     end
 end
 
+"""
+    contextual_isassumption(context, vn)
+
+Return `true` if `vn` is considered an assumption by `context`.
+
+The default implementation for `AbstractContext` always returns `true`.
+"""
+contextual_isassumption(::IsLeaf, context, vn) = true
+function contextual_isassumption(::IsParent, context, vn)
+    return contextual_isassumption(childcontext(context), vn)
+end
+function contextual_isassumption(context::AbstractContext, vn)
+    return contextual_isassumption(NodeTrait(context), context, vn)
+end
+function contextual_isassumption(context::ConditionContext, vn)
+    if hasvalue(context, vn)
+        val = getvalue(context, vn)
+        # TODO: Do we even need the `>: Missing` to help the compiler?
+        if eltype(val) >: Missing && val === missing
+            return true
+        end
+    end
+
+    # We might have nested contexts, e.g. `ContextionContext{.., <:PrefixContext{..., <:ConditionContext}}`
+    # so we defer to `childcontext` if we haven't concluded that anything yet.
+    return contextual_isassumption(childcontext(context), vn)
+end
+function contextual_isassumption(context::PrefixContext, vn)
+    return contextual_isassumption(childcontext(context), prefix(context, vn))
+end
+
 # failsafe: a literal is never an assumption
 isassumption(expr) = :(false)
 
@@ -336,6 +381,11 @@ function generate_tilde(left, right)
                 __varinfo__,
             )
         else
+            # If `vn` is not in `argnames`, we need to make sure that the variable is defined.
+            if !$(DynamicPPL.inargnames)($vn, __model__)
+                $left = $(DynamicPPL.getvalue)(__context__, $vn)
+            end
+
             $(DynamicPPL.tilde_observe!)(
                 __context__,
                 $(DynamicPPL.check_tilde_rhs)($right),
@@ -380,6 +430,11 @@ function generate_dot_tilde(left, right)
                 __varinfo__,
             )
         else
+            # If `vn` is not in `argnames`, we need to make sure that the variable is defined.
+            if !$(DynamicPPL.inargnames)($vn, __model__)
+                $left .= $(DynamicPPL.getvalue)(__context__, $vn)
+            end
+
             $(DynamicPPL.dot_tilde_observe!)(
                 __context__,
                 $(DynamicPPL.check_tilde_rhs)($right),

src/context_implementations.jl

@@ -14,8 +14,17 @@ alg_str(spl::Sampler) = string(nameof(typeof(spl.alg)))
 require_gradient(spl::Sampler) = false
 require_particles(spl::Sampler) = false
 
-_getindex(x, inds::Tuple) = _getindex(view(x, first(inds)...), Base.tail(inds))
+_getindex(x, inds::Tuple) = _getindex(Base.maybeview(x, first(inds)...), Base.tail(inds))
 _getindex(x, inds::Tuple{}) = x
+_getvalue(x, vn::VarName{sym}) where {sym} = _getindex(getproperty(x, sym), vn.indexing)
+function _getvalue(x, vns::AbstractVector{<:VarName{sym}}) where {sym}
+    val = getproperty(x, sym)
+
+    # This should work with both cartesian and linear indexing.
+    return map(vns) do vn
+        _getindex(val, vn)
+    end
+end
 
 # assume
 """

src/contexts.jl

@@ -239,3 +239,180 @@ function prefix(::PrefixContext{Prefix}, vn::VarName{Sym}) where {Prefix,Sym}
         VarName{Symbol(Prefix, PREFIX_SEPARATOR, Sym)}(vn.indexing)
     end
 end
+
+struct ConditionContext{Names,Values,Ctx<:AbstractContext} <: AbstractContext
+    values::Values
+    context::Ctx
+
+    function ConditionContext{Values}(
+        values::Values, context::AbstractContext
+    ) where {names,Values<:NamedTuple{names}}
+        return new{names,typeof(values),typeof(context)}(values, context)
+    end
+end
+
+function ConditionContext(values::NamedTuple)
+    return ConditionContext(values, DefaultContext())
+end
+function ConditionContext(values::NamedTuple, context::AbstractContext)
+    return ConditionContext{typeof(values)}(values, context)
+end
+
+# Try to avoid nested `ConditionContext`.
+function ConditionContext(
+    values::NamedTuple{Names}, context::ConditionContext
+) where {Names}
+    # Note that this potentially overrides values from `context`, thus giving
+    # precedence to the outmost `ConditionContext`.
+    return ConditionContext(merge(context.values, values), childcontext(context))
+end
+
+function Base.show(io::IO, context::ConditionContext)
+    return print(io, "ConditionContext($(context.values), $(childcontext(context)))")
+end
+
+NodeTrait(context::ConditionContext) = IsParent()
+childcontext(context::ConditionContext) = context.context
+setchildcontext(parent::ConditionContext, child) = ConditionContext(parent.values, child)
+
+"""
+    getvalue(context, vn)
+
+Return the value of the parameter corresponding to `vn` from `context`.
+If `context` does not contain the value for `vn`, then `nothing` is returned,
+e.g. [`DefaultContext`](@ref) will always return `nothing`.
+"""
+getvalue(::IsLeaf, context, vn) = nothing
+getvalue(::IsParent, context, vn) = getvalue(childcontext(context), vn)
+getvalue(context::AbstractContext, vn) = getvalue(NodeTrait(getvalue, context), context, vn)
+getvalue(context::PrefixContext, vn) = getvalue(childcontext(context), prefix(context, vn))
+
+function getvalue(context::ConditionContext, vn)
+    return if hasvalue(context, vn)
+        _getvalue(context.values, vn)
+    else
+        getvalue(childcontext(context), vn)
+    end
+end
+
+# General implementations of `haskey`.
+hasvalue(::IsLeaf, context, vn) = false
+hasvalue(::IsParent, context, vn) = hasvalue(childcontext(context), vn)
+hasvalue(context::AbstractContext, vn) = hasvalue(NodeTrait(context), context, vn)
+
+# Specific to `ConditionContext`.
+function hasvalue(context::ConditionContext{vars}, vn::VarName{sym}) where {vars,sym}
+    # TODO: Add possibility of indexed variables, e.g. `x[1]`, etc.
+    return sym in vars
+end
+
+function hasvalue(
+    context::ConditionContext{vars}, vn::AbstractArray{<:VarName{sym}}
+) where {vars,sym}
+    # TODO: Add possibility of indexed variables, e.g. `x[1]`, etc.
+    return sym in vars
+end
+
+"""
+    context([context::AbstractContext,] values::NamedTuple)
+    context([context::AbstractContext]; values...)
+
+Return `ConditionContext` with `values` and `context` if `values` is non-empty,
+otherwise return `context` which is [`DefaultContext`](@ref) by default.
+
+See also: [`decondition`](@ref)
+"""
+condition(; values...) = condition(DefaultContext(), (; values...))
+condition(values::NamedTuple) = condition(DefaultContext(), values)
+condition(context::AbstractContext, values::NamedTuple{()}) = context
+condition(context::AbstractContext, values::NamedTuple) = ConditionContext(values, context)
+condition(context::AbstractContext; values...) = condition(context, (; values...))
+"""
+    decondition(context::AbstractContext, syms...)
+
+Return `context` but with `syms` no longer conditioned on.
+
+Note that this recursively traverses contexts, deconditioning all along the way.
+
+See also: [`condition`](@ref)
+
+# Examples
+```jldoctest
+julia> using DynamicPPL: AbstractContext, leafcontext, setleafcontext, childcontext, setchildcontext
+
+julia> struct ParentContext{C} <: AbstractContext
+           context::C
+       end
+
+julia> DynamicPPL.NodeTrait(::ParentContext) = DynamicPPL.IsParent()
+
+julia> DynamicPPL.childcontext(context::ParentContext) = context.context
+
+julia> DynamicPPL.setchildcontext(::ParentContext, child) = ParentContext(child)
+
+julia> Base.show(io::IO, c::ParentContext) = print(io, "ParentContext(", childcontext(c), ")")
+
+julia> ctx = DefaultContext()
+DefaultContext()
+
+julia> decondition(ctx) === ctx # this is a no-op
+true
+
+julia> ctx = condition(x = 1.0) # default "constructor" for `ConditionContext`
+ConditionContext((x = 1.0,), DefaultContext())
+
+julia> decondition(ctx) # `decondition` without arguments drops all conditioning
+DefaultContext()
+
+julia> # Nested conditioning is supported.
+       ctx_nested = condition(ParentContext(condition(y=2.0)), x=1.0)
+ConditionContext((x = 1.0,), ParentContext(ConditionContext((y = 2.0,), DefaultContext())))
+
+julia> # We can also specify which variables to drop.
+       decondition(ctx_nested, :x)
+ParentContext(ConditionContext((y = 2.0,), DefaultContext()))
+
+julia> # No matter the nested level.
+       decondition(ctx_nested, :y)
+ConditionContext((x = 1.0,), ParentContext(DefaultContext()))
+
+julia> # Or specify multiple at in one call.
+       decondition(ctx_nested, :x, :y)
+ParentContext(DefaultContext())
+
+julia> decondition(ctx_nested)
+ParentContext(DefaultContext())
+
+julia> # `Val` is also supported.
+       decondition(ctx_nested, Val(:x))
+ParentContext(ConditionContext((y = 2.0,), DefaultContext()))
+
+julia> decondition(ctx_nested, Val(:y))
+ConditionContext((x = 1.0,), ParentContext(DefaultContext()))
+
+julia> decondition(ctx_nested, Val(:x), Val(:y))
+ParentContext(DefaultContext())
+```
+"""
+decondition(::IsLeaf, context, args...) = context
+function decondition(::IsParent, context, args...)
+    return setchildcontext(context, decondition(childcontext(context), args...))
+end
+decondition(context, args...) = decondition(NodeTrait(context), context, args...)
+function decondition(context::ConditionContext)
+    return decondition(childcontext(context))
+end
+function decondition(context::ConditionContext, sym)
+    return condition(
+        decondition(childcontext(context), sym), BangBang.delete!!(context.values, sym)
+    )
+end
+function decondition(context::ConditionContext, sym, syms...)
+    return decondition(
+        condition(
+            decondition(childcontext(context), syms...),
+            BangBang.delete!!(context.values, sym),
+        ),
+        syms...,
+    )
+end

src/contextual_model.jl

@@ -0,0 +1,27 @@
+struct ContextualModel{Ctx<:AbstractContext,M<:Model} <: AbstractModel
+    context::Ctx
+    model::M
+end
+
+function contextualize(model::AbstractModel, context::AbstractContext)
+    return ContextualModel(context, model)
+end
+
+# TODO: What do we do for other contexts? Could handle this in general if we had a
+# notion of wrapper-, primitive-context, etc.
+function _evaluate(cmodel::ContextualModel{<:ConditionContext}, varinfo, context)
+    # Wrap `context` in the model-associated `ConditionContext`, but now using `context` as
+    # `ConditionContext` child.
+    return _evaluate(cmodel.model, varinfo, setchildcontext(cmodel.context, context))
+end
+
+condition(model::AbstractModel, values) = contextualize(model, ConditionContext(values))
+condition(model::AbstractModel; values...) = condition(model, (; values...))
+function condition(cmodel::ContextualModel{<:ConditionContext}, values)
+    return contextualize(cmodel.model, ConditionContext(values, cmodel.context))
+end
+
+decondition(model::AbstractModel, args...) = model
+function decondition(cmodel::ContextualModel{<:ConditionContext}, syms...)
+    return contextualize(cmodel.model, decondition(cmodel.context, syms...))
+end