OETH Oracle

contracts/contracts/interfaces/IVault.sol

@@ -120,6 +120,8 @@ interface IVault {
 
     function priceUnitRedeem(address asset) external view returns (uint256);
 
+    function floorPrice() external view returns (uint256);
+
     function withdrawAllFromStrategy(address _strategyAddr) external;
 
     function withdrawAllFromStrategies() external;

contracts/contracts/interfaces/chainlink/README.md

@@ -0,0 +1,3 @@
+# Diagrams
+
+![AggregatorV3Interface](../../../docs/AggregatorV3Interface.svg)

contracts/contracts/mocks/MockVault.sol

@@ -10,6 +10,7 @@ contract MockVault is VaultCore {
     using StableMath for uint256;
 
     uint256 storedTotalValue;
+    uint256 public override floorPrice;
 
     function setTotalValue(uint256 _value) public {
         storedTotalValue = _value;
@@ -42,4 +43,8 @@ contract MockVault is VaultCore {
     function setMaxSupplyDiff(uint256 _maxSupplyDiff) external onlyGovernor {
         maxSupplyDiff = _maxSupplyDiff;
     }
+
+    function setFloorPrice(uint256 _floorPrice) external {
+        floorPrice = _floorPrice;
+    }
 }

contracts/contracts/mocks/curve/MockCurveOethEthPool.sol

@@ -0,0 +1,20 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.0;
+
+import { MockCurveAbstractMetapool } from "./MockCurveAbstractMetapool.sol";
+import "../MintableERC20.sol";
+
+contract MockCurveOethEthPool is MockCurveAbstractMetapool {
+    constructor(address[2] memory _coins)
+        ERC20("Curve.fi Factory Pool: OETH", "OETHCRV-f")
+    {
+        coins = _coins;
+    }
+
+    // Simulate pool's EMA Oracle price
+    uint256 public price_oracle = 9995e14; // 0.9995
+
+    function setOraclePrice(uint256 _price) public {
+        price_oracle = _price;
+    }
+}

contracts/contracts/oracle/BaseOracle.sol

@@ -0,0 +1,202 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.0;
+
+import { IOracleReceiver } from "./IOracleReceiver.sol";
+import { AggregatorV3Interface } from "../interfaces/chainlink/AggregatorV3Interface.sol";
+import { Governable } from "../governance/Governable.sol";
+
+/**
+ * @title BaseOracle
+ * @notice Generic Chainlink style oracle
+ * @author Origin Protocol Inc
+ */
+abstract contract BaseOracle is
+    AggregatorV3Interface,
+    IOracleReceiver,
+    Governable
+{
+    /// @notice Contract or account that can call addRoundData() to update the Oracle prices
+    address public oracleUpdater;
+
+    /// @notice Last round ID where isBadData is false and price is within maximum deviation
+    uint80 public lastCorrectRoundId;
+
+    /// @notice Historical Oracle prices
+    Round[] public rounds;
+
+    /// @notice Packed Round data struct
+    /// @notice price Oracle price to 18 decimals
+    /// @notice timestamp timestamp in seconds of price
+    struct Round {
+        uint128 price;
+        uint40 timestamp;
+    }
+
+    event SetOracleUpdater(address oracleUpdater);
+
+    constructor(address _oracleUpdater) Governable() {
+        _setOracleUpdater(_oracleUpdater);
+    }
+
+    /***************************************
+                Internal Setters
+    ****************************************/
+
+    /// @notice Sets the contract or account that can add Oracle prices
+    /// @param _oracleUpdater Address of the contract or account that can update the Oracle prices
+    function _setOracleUpdater(address _oracleUpdater) internal {
+        emit SetOracleUpdater(_oracleUpdater);
+        oracleUpdater = _oracleUpdater;
+    }
+
+    /***************************************
+                External Setters
+    ****************************************/
+
+    /// @notice Sets the contract or account that can update the Oracle prices
+    /// @param _oracleUpdater Address of the contract or account that can update the Oracle prices
+    function setOracleUpdater(address _oracleUpdater) external onlyGovernor {
+        _setOracleUpdater(_oracleUpdater);
+    }
+
+    /***************************************
+                Metadata
+    ****************************************/
+
+    /// @notice The number of decimals in the Oracle price.
+    function decimals()
+        external
+        pure
+        virtual
+        override
+        returns (uint8 _decimals)
+    {
+        _decimals = 18;
+    }
+
+    /// @notice The version number for the AggregatorV3Interface.
+    /// @dev Adheres to AggregatorV3Interface, which is different than typical semver
+    function version()
+        external
+        view
+        virtual
+        override
+        returns (uint256 _version)
+    {
+        _version = 1;
+    }
+
+    /***************************************
+                Oracle Receiver
+    ****************************************/
+
+    /// @notice Adds a new Oracle price by the Oracle updater.
+    /// Can not be run twice in the same block.
+    /// @param _price is the Oracle price with 18 decimals
+    function addPrice(uint128 _price) external override {
+        if (msg.sender != oracleUpdater) revert OnlyOracleUpdater();
+        if (_price == 0) revert NoPriceData();
+
+        // Can not add price in the same or previous blocks
+        uint256 _roundsLength = rounds.length;
+        if (
+            _roundsLength > 0 &&
+            block.timestamp <= rounds[_roundsLength - 1].timestamp
+        ) {
+            revert AddPriceSameBlock();
+        }
+
+        lastCorrectRoundId = uint80(_roundsLength);
+
+        rounds.push(
+            Round({ price: _price, timestamp: uint40(block.timestamp) })
+        );
+    }
+
+    /***************************************
+                Prices
+    ****************************************/
+
+    function _getRoundData(uint80 _roundId)
+        internal
+        view
+        returns (
+            uint80 roundId,
+            int256 answer,
+            uint256 startedAt,
+            uint256 updatedAt,
+            uint80 answeredInRound
+        )
+    {
+        if (rounds.length <= _roundId) revert NoPriceData();
+
+        Round memory _round = rounds[_roundId];
+        answer = int256(uint256(_round.price));
+
+        roundId = answeredInRound = _roundId;
+        startedAt = updatedAt = _round.timestamp;
+    }
+
+    /// @notice Returns the Oracle price data for a specific round.
+    /// @param _roundId The round ID
+    /// @return roundId The round ID
+    /// @return answer The Oracle price
+    /// @return startedAt Timestamp of when the round started
+    /// @return updatedAt Timestamp of when the round was updated
+    /// @return answeredInRound The round ID in which the answer was computed
+    function getRoundData(uint80 _roundId)
+        external
+        view
+        override
+        returns (
+            uint80 roundId,
+            int256 answer,
+            uint256 startedAt,
+            uint256 updatedAt,
+            uint80 answeredInRound
+        )
+    {
+        (
+            roundId,
+            answer,
+            startedAt,
+            updatedAt,
+            answeredInRound
+        ) = _getRoundData(_roundId);
+    }
+
+    /// @notice Returns the latest Oracle price data.
+    /// @return roundId The round ID
+    /// @return answer The Oracle price
+    /// @return startedAt Timestamp of when the round started
+    /// @return updatedAt Timestamp of when the round was updated
+    /// @return answeredInRound The round ID in which the answer was computed
+    function latestRoundData()
+        external
+        view
+        override
+        returns (
+            uint80 roundId,
+            int256 answer,
+            uint256 startedAt,
+            uint256 updatedAt,
+            uint80 answeredInRound
+        )
+    {
+        (
+            roundId,
+            answer,
+            startedAt,
+            updatedAt,
+            answeredInRound
+        ) = _getRoundData(lastCorrectRoundId);
+    }
+
+    /***************************************
+                Errors
+    ****************************************/
+
+    error AddPriceSameBlock();
+    error NoPriceData();
+    error OnlyOracleUpdater();
+}

contracts/contracts/oracle/IOracleReceiver.sol

@@ -0,0 +1,6 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.0;
+
+interface IOracleReceiver {
+    function addPrice(uint128 price) external;
+}

contracts/contracts/oracle/OETHOracle.sol

@@ -0,0 +1,18 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.0;
+
+import { BaseOracle } from "./BaseOracle.sol";
+
+/**
+ * @title OETH Oracle
+ * @notice Chainlink style oracle for OETH/ETH
+ * @author Origin Protocol Inc
+ */
+contract OETHOracle is BaseOracle {
+    string public constant override description = "OETH / ETH";
+
+    /**
+     * @param _oracleUpdater Address of the contract that is authorized to add prices
+     */
+    constructor(address _oracleUpdater) BaseOracle(_oracleUpdater) {}
+}