Add smoke test for binary package

Author: guyang3532

windows/internal/smoke_test.bat

@@ -0,0 +1,193 @@
+set SRC_DIR=%~dp0
+pushd %SRC_DIR%\..
+
+set "ORIG_PATH=%PATH%"
+
+setlocal EnableDelayedExpansion
+set NVIDIA_GPU_EXISTS=0
+for /F "delims=" %%i in ('wmic path win32_VideoController get name') do (
+    set GPUS=%%i
+    if not "x!GPUS:NVIDIA=!" == "x!GPUS!" (
+        SET NVIDIA_GPU_EXISTS=1
+        goto gpu_check_end
+    )
+)
+:gpu_check_end
+endlocal & set NVIDIA_GPU_EXISTS=%NVIDIA_GPU_EXISTS%
+
+if "%PACKAGE_TYPE%" == "wheel" goto wheel
+if "%PACKAGE_TYPE%" == "conda" goto conda
+if "%PACKAGE_TYPE%" == "libtorch" goto libtorch
+
+:wheel
+echo "install wheel package"
+
+set PYTHON_INSTALLER_URL=
+if "%DESIRED_PYTHON%" == "3.8" set "PYTHON_INSTALLER_URL=https://www.python.org/ftp/python/3.8.2/python-3.8.2-amd64.exe"
+if "%DESIRED_PYTHON%" == "3.7" set "PYTHON_INSTALLER_URL=https://www.python.org/ftp/python/3.7.7/python-3.7.7-amd64.exe"
+if "%DESIRED_PYTHON%" == "3.6" set "PYTHON_INSTALLER_URL=https://www.python.org/ftp/python/3.6.8/python-3.6.8-amd64.exe"
+if "%PYTHON_INSTALLER_URL%" == "" (
+    echo Python %DESIRED_PYTHON% not supported yet
+)
+
+del python-amd64.exe
+curl --retry 3 -kL "%PYTHON_INSTALLER_URL%" --output python-amd64.exe
+if errorlevel 1 exit /b 1
+
+start /wait "" python-amd64.exe /quiet InstallAllUsers=1 PrependPath=1 Include_test=0 TargetDir=%CD%\Python%PYTHON_VERSION%
+if errorlevel 1 exit /b 1
+
+set "PATH=%CD%\Python%PYTHON_VERSION%\Scripts;%CD%\Python%PYTHON_VERSION%;%PATH%"
+
+for /F "delims=" %%i in ('where /R "%PYTORCH_FINAL_PACKAGE_DIR:/=\%" *.whl') do pip install "%%i"
+pip install -q future numpy protobuf six "mkl>=2019"
+goto smoke_test
+
+:conda
+echo "install conda package"
+
+:: Install Miniconda3
+set "CONDA_HOME=%CD%\conda"
+set "tmp_conda=%CONDA_HOME%"
+set "miniconda_exe=%CD%\miniconda.exe"
+
+rmdir /s /q conda
+del miniconda.exe
+curl -k https://repo.anaconda.com/miniconda/Miniconda3-latest-Windows-x86_64.exe -o "%miniconda_exe%"
+call ..\conda\install_conda.bat
+if ERRORLEVEL 1 exit /b 1
+
+set "PATH=%CONDA_HOME%;%CONDA_HOME%\scripts;%CONDA_HOME%\Library\bin;%PATH%"
+
+conda create -qyn testenv python=%DESIRED_PYTHON%
+source activate testenv >/dev/null
+for /F "delims=" %%i in ('where /R "%PYTORCH_FINAL_PACKAGE_DIR:/=\%" *.tar.bz2') do conda install -y "%%i" --offline
+conda install -yq future numpy protobuf six
+
+set /a CUDA_VER=%CUDA_VERSION%
+set CUDA_VER_MAJOR=%CUDA_VERSION:~0,-1%
+set CUDA_VER_MINOR=%CUDA_VERSION:~-1,1%
+set CUDA_VERSION_STR=%CUDA_VER_MAJOR%.%CUDA_VER_MINOR%
+conda install -yq -c pytorch "cudatoolkit=%CUDA_VERSION_STR%"
+
+:smoke_test
+python -c "import torch"
+if ERRORLEVEL 1 exit /b 1
+
+python -c "from caffe2.python import core"
+if ERRORLEVEL 1 exit /b 1
+
+echo Checking that MKL is available
+python -c "import torch; exit(0 if torch.backends.mkl.is_available() else 1)"
+if ERRORLEVEL 1 exit /b 1
+
+if "%NVIDIA_GPU_EXISTS%" == "0" (
+    echo "Skip CUDA tests for machines without a Nvidia GPU card"
+    goto end
+)
+
+echo Checking that CUDA archs are setup correctly
+python -c "import torch; torch.randn([3,5]).cuda()"
+if ERRORLEVEL 1 exit /b 1
+
+echo Checking that magma is available
+python -c "import torch; torch.rand(1).cuda(); exit(0 if torch.cuda.has_magma else 1)"
+if ERRORLEVEL 1 exit /b 1
+
+echo Checking that CuDNN is available
+python -c "import torch; exit(0 if torch.backends.cudnn.is_available() else 1)"
+if ERRORLEVEL 1 exit /b 1
+
+goto end
+
+:libtorch
+echo "install and test libtorch"
+
+powershell internal/vs_install.ps1
+if ERRORLEVEL 1 exit /b 1
+
+for /F "delims=" %%i in ('where /R "%PYTORCH_FINAL_PACKAGE_DIR:/=\%" *-latest.zip') do unzip "%%i" -d tmp
+pushd tmp\libtorch
+
+for /f "usebackq tokens=*" %%i in (`"%ProgramFiles(x86)%\Microsoft Visual Studio\Installer\vswhere.exe" -legacy -products * -version [15^,16^) -property installationPath`) do (
+    if exist "%%i" if exist "%%i\VC\Auxiliary\Build\vcvarsall.bat" (
+        set "VS15INSTALLDIR=%%i"
+        set "VS15VCVARSALL=%%i\VC\Auxiliary\Build\vcvarsall.bat"
+        goto vswhere
+    )
+)
+
+:vswhere
+IF "%VS15VCVARSALL%"=="" (
+    echo Visual Studio 2017 C++ BuildTools is required to compile PyTorch on Windows
+    exit /b 1
+)
+call "%VS15VCVARSALL%" x64
+
+set install_root=%CD%
+set INCLUDE=%INCLUDE%;%install_root%/include;%install_root%/include/torch/csrc/api/include
+set LIB=%LIB%;%install_root%/lib
+set PATH=%PATH%;%install_root%/lib
+
+>example-app.cpp (
+echo #include ^<torch/torch.h^>
+echo int main(int argc, const char* argv[]^) {
+echo    TORCH_WARN("Simple test passed!"^);
+echo    return 0;
+echo }
+)
+
+del example-app.exe
+cl example-app.cpp c10.lib torch_cpu.lib /EHsc
+.\example-app.exe
+if ERRORLEVEL 1 exit /b 1
+
+echo Checking that MKL is available
+del example-app.cpp
+>example-app.cpp (
+echo #include ^<torch/torch.h^>
+echo int main(int argc, const char* argv[]^) {
+echo  TORCH_CHECK(torch::hasMKL(^), "MKL is not available"^);
+echo  return 0;
+echo }
+)
+
+del example-app.exe
+cl example-app.cpp c10.lib torch_cpu.lib /EHsc
+.\example-app.exe
+if ERRORLEVEL 1 exit /b 1
+
+if "%NVIDIA_GPU_EXISTS%" == "0" (
+    echo "Skip CUDA tests for machines without a Nvidia GPU card"
+    goto end
+)
+
+del example-app.cpp
+>example-app.cpp (
+echo #include ^<torch/torch.h^>
+echo int main(int argc, const char* argv[]^) {
+echo  std::cout ^<^< "Checking that CUDA archs are setup correctly" ^<^< std::endl;
+echo  TORCH_CHECK(torch::rand({3, 5}, torch::Device(torch::kCUDA^)^).defined(^), "CUDA archs are not setup correctly"^);
+echo.
+echo  // These have to run after CUDA is initialized
+echo.
+echo  std::cout ^<^< "Checking that magma is available" ^<^< std::endl;
+echo  TORCH_CHECK(torch::hasMAGMA(^), "MAGMA is not available"^);
+echo.
+echo  std::cout ^<^< "Checking that CuDNN is available" ^<^< std::endl;
+echo  TORCH_CHECK(torch::cuda::cudnn_is_available(^), "CuDNN is not available"^);
+echo  std::cout.flush(^);
+echo  return 0;
+echo }
+)
+
+del example-app.exe
+cl example-app.cpp torch_cpu.lib c10.lib torch_cuda.lib /EHsc /link /INCLUDE:?warp_size@cuda@at@@YAHXZ
+.\example-app.exe
+if ERRORLEVEL 1 exit /b 1
+
+popd
+
+:end
+set "PATH=%ORIG_PATH%"
+popd