pybind11 cmake target and Config

Author: loriab

CMakeLists.txt

@@ -179,8 +179,41 @@ if (PYBIND11_TEST)
   add_subdirectory(tests)
 endif()
 
+include(GNUInstallDirs)
+include(CMakePackageConfigHelpers)
+
+# Build an interface library target:
+#   Though any project using pybind11 will need to include python headers and
+#   define c++11/14-ness, these are not included as interface includes or compile
+#   defs because (1) that's really the domain of the upstream project to decide,
+#   (2) we can get away with it since installation (headers) don't care about
+#   python version or C++ standard, and (3) this will make the easily target relocatable.
+add_library(pb11 INTERFACE)
+set_target_properties(pb11 PROPERTIES EXPORT_NAME "pybind11")
+target_include_directories(pb11 INTERFACE $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>)
+if(APPLE)
+    target_link_libraries(pb11 INTERFACE "-undefined dynamic_lookup")
+endif()
+
 if (PYBIND11_INSTALL)
-  include(GNUInstallDirs)
   install(FILES ${PYBIND11_HEADERS}
           DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/pybind11)
+  install(TARGETS pb11
+          EXPORT "${PROJECT_NAME}Targets")
+
+      # explicit "share" not "DATADIR" for CMake search path
+  set(CMAKECONFIG_INSTALL_DIR "share/cmake/${PROJECT_NAME}")
+  configure_package_config_file(tools/${PROJECT_NAME}Config.cmake.in
+                                "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}Config.cmake"
+                                INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR})
+  write_basic_package_version_file(${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}ConfigVersion.cmake
+                                   VERSION 1.8
+                                   #VERSION ${${PROJECT_NAME}_VERSION}
+                                   COMPATIBILITY AnyNewerVersion)
+  install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}Config.cmake
+                ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}ConfigVersion.cmake
+          DESTINATION ${CMAKECONFIG_INSTALL_DIR})
+  install(EXPORT "${PROJECT_NAME}Targets"
+          NAMESPACE "${PROJECT_NAME}::"
+          DESTINATION ${CMAKECONFIG_INSTALL_DIR})
 endif()

tools/pybind11Config.cmake.in

@@ -0,0 +1,82 @@
+# pybind11Config.cmake
+# --------------------
+#
+# PYBIND11 cmake module.
+# This module sets the following variables in your project:
+#
+# ::
+#
+#   pybind11_FOUND - true if pybind11 and all required components found on the system
+#   pybind11_VERSION - pybind11 version in format Major.Minor.Release
+#   pybind11_INCLUDE_DIRS - Directory where pybind11 headers are located.
+#   pybind11_INCLUDE_DIR - same as DIRS
+#
+#
+# Available components: None
+#
+#
+# Exported targets:
+#
+# ::
+#
+# If pybind11 is found, this module defines the following :prop_tgt:`IMPORTED`
+# target. Note that python headers and C++ standard (11 or 14) of your choice and
+# detection will need to be applied to your code ::
+#
+#   pybind11::pybind11 - the main pybind11 interface library (i.e., headers) 
+#
+#   find_package(PythonLibsNew REQUIRED)
+#   find_package(pybind11 CONFIG REQUIRED)
+#   message(STATUS "Found pybind11: ${pybind11_INCLUDE_DIR} (found version ${pybind11_VERSION})")
+#   set_property(TARGET pybind11::pybind11 APPEND PROPERTY INTERFACE_INCLUDE_DIRECTORIES ${PYTHON_INCLUDE_DIRS}
+#                                                          INTERFACE_COMPILE_OPTIONS "-std=c++11")
+#
+#
+# Suggested usage:
+#
+# ::
+#
+#   find_package(pybind11)
+#   find_package(pybind11 2.0 EXACT CONFIG REQUIRED)
+#
+#
+# The following variables can be set to guide the search for this package:
+#
+# ::
+#
+#   pybind11_DIR - CMake variable, set to directory containing this Config file
+#   CMAKE_PREFIX_PATH - CMake variable, set to root directory of this package
+#   PATH - environment variable, set to bin directory of this package
+#   CMAKE_DISABLE_FIND_PACKAGE_pybind11 - CMake variable, disables
+#     find_package(pybind11) when not REQUIRED, perhaps to force internal build
+
+@PACKAGE_INIT@
+
+set(PN pybind11)
+
+# find includes
+unset(_temp_h CACHE)
+find_path(_temp_h
+          NAMES pybind11/pybind11.h
+          PATHS ${PACKAGE_PREFIX_DIR}/@CMAKE_INSTALL_INCLUDEDIR@
+          NO_DEFAULT_PATH)
+if(_temp_h)
+    set(${PN}_INCLUDE_DIR "${_temp_h}")
+    set(${PN}_INCLUDE_DIRS ${${PN}_INCLUDE_DIR})
+else()
+    set(${PN}_FOUND 0)
+    if(NOT CMAKE_REQUIRED_QUIET)
+        message(STATUS "${PN}Config missing component: header (${PN}: ${_temp_h})")
+    endif()
+endif()
+
+check_required_components(${PN})
+
+#-----------------------------------------------------------------------------
+# Don't include targets if this file is being picked up by another
+# project which has already built this as a subproject
+#-----------------------------------------------------------------------------
+if(NOT TARGET ${PN}::pybind11)
+    include("${CMAKE_CURRENT_LIST_DIR}/${PN}Targets.cmake")
+endif()
+