Some convenience functions for graders

Author: adhameer

src/grader/learnocaml_report.ml

@@ -109,6 +109,21 @@ let result items =
   let (n, b) = do_report items in
   (max n 0, b)
 
+let rec scale ?(penalties = true) factor items =
+  List.map (scale_item penalties factor) items
+and scale_item penalties factor = function
+  | Section (text, report) ->
+      Section (text, scale ~penalties factor report)
+  | SectionMin (text, report, min) ->
+      SectionMin (text,
+                  scale ~penalties factor report,
+                  if penalties then factor * min else min)
+  | Message (text, Success n) ->
+      Message (text, Success (factor * n))
+  | Message (text, Penalty n) when penalties ->
+      Message (text, Penalty (factor * n))
+  | item -> item
+
 let enc =
   let open Json_encoding in
   let text_enc =

src/grader/learnocaml_report.mli

@@ -34,6 +34,13 @@ and inline =
 (** Gets the total successes of a report, and tells if a failure happened *)
 val result : t -> int * bool
 
+(** Scales all of the point values of the items in a report by an integer
+    factor. Useful for weighting different components of an exercise.
+    If [penalties] ([true] by default), scales the values of [Penalty]
+    items and the minimum values for [SectionMin], otherwise leaves them
+    untouched. *)
+val scale : ?penalties: bool -> int -> t -> t
+
 (** Gets a report as HTML in a string
     (if [not bare] add a container div and inline style) *)
 val to_html :  ?bare: bool -> t -> string

src/grader/test_lib.ml

@@ -461,6 +461,8 @@ module type S = sig
   end
 
   val (@@@) : ('a -> Learnocaml_report.t) -> ('a -> Learnocaml_report.t) -> ('a -> Learnocaml_report.t)
+  val (@@>) : Learnocaml_report.t -> (unit -> Learnocaml_report.t) -> Learnocaml_report.t
+  val (@@=) : Learnocaml_report.t -> (unit -> Learnocaml_report.t) -> Learnocaml_report.t
 
   (**/**)
   include (module type of Ast_checker)
@@ -1883,6 +1885,9 @@ module Make
   end
 
   let (@@@) f g = fun x -> f x @ g x
+  let (@@>) r1 f = if snd (Learnocaml_report.result r1) then r1 else f ()
+  let (@@=) r1 f = if snd (Learnocaml_report.result r1) then r1 else r1 @ f ()
+
   (**/**)
   include Ast_checker
   include Tester

src/grader/test_lib.mli

@@ -1243,6 +1243,22 @@ module type S = sig
      -> ('a -> Learnocaml_report.t)
      -> ('a -> Learnocaml_report.t)
 
+   (** [r1 @@> f] returns [r1] if [r1] is a failure report,
+       otherwise returns the result of report generator
+       [f ()]. *)
+   val (@@>) :
+     Learnocaml_report.t
+     -> (unit -> Learnocaml_report.t)
+     -> Learnocaml_report.t
+
+   (** [r1 @@= f] returns [r1] if [r1] is a failure report,
+       otherwise concatenates [r1] to the result of report
+       generator [f ()]. *)
+   val (@@=) :
+     Learnocaml_report.t
+     -> (unit -> Learnocaml_report.t)
+     -> Learnocaml_report.t
+
    (**/**)
    include (module type of Ast_checker)
    include (module type of Tester)