Add tiles around point to tile module

Author: jericks

examples/tile_map_at_point.groovy

@@ -0,0 +1,20 @@
+import geoscript.geom.Geometry
+import geoscript.geom.Point
+import geoscript.layer.OSM
+import geoscript.layer.Raster
+import geoscript.proj.Projection
+import javax.imageio.ImageIO
+
+OSM osm = new OSM()
+
+[
+    "POINT (-100.777587890625 46.800059446787316)",
+    "POINT (-122.38494873046875 47.570966845786124)",
+    "POINT (12.5244140625 42.032974332441405)",
+    "POINT (23.752441406249996 38.004819966413194)"
+].eachWithIndex { String wkt, int i ->
+    [1,4,8,16].each {int z ->
+        Raster raster = osm.getRaster(Projection.transform(Geometry.fromWKT(wkt), "EPSG:4326", "EPSG:3857") as Point, z, 400, 400)
+        ImageIO.write(raster.image, "png", new File("map_at_point_${i}_${z}.png"))
+    }
+}

src/main/groovy/geoscript/layer/ImageTileLayer.groovy

@@ -1,6 +1,7 @@
 package geoscript.layer
 
 import geoscript.geom.Bounds
+import geoscript.geom.Point
 import geoscript.style.RasterSymbolizer
 import org.geotools.map.GridCoverageLayer
 
@@ -71,6 +72,18 @@ abstract class ImageTileLayer extends TileLayer<ImageTile> implements Renderable
         }
     }
 
+    /**
+     * Get a Raster around a Point at a given zoom level
+     * @param p The Point (in the TileLayer's projection)
+     * @param z The zoom level
+     * @param w The image width
+     * @param h The image height
+     * @return A Raster
+     */
+    Raster getRaster(Point p, long z, int w, int h) {
+        getRaster(this.pyramid.bounds(p, z, w, h), w, h)
+    }
+
     @Override
     List<org.geotools.map.Layer> getMapLayers(Bounds bounds, List size) {
         def raster = this.getRaster(bounds.reproject(this.proj), size[0], size[1])

src/main/groovy/geoscript/layer/Pyramid.groovy

@@ -1,6 +1,7 @@
 package geoscript.layer
 
 import geoscript.geom.Bounds
+import geoscript.geom.Point
 import geoscript.layer.io.PyramidReader
 import geoscript.layer.io.PyramidReaders
 import geoscript.proj.Projection
@@ -115,6 +116,21 @@ class Pyramid {
         grids.min { Grid g -> g.z }
     }
 
+    /**
+     * Find the Bounds around a Point at a given zoom level for a canvas of a given width and height
+     * @param p The Point (in the Pyramid's projection)
+     * @param z The zoom level
+     * @param width The canvas width
+     * @param height The canvas height
+     * @return a Bounds
+     */
+    Bounds bounds(Point p, long z, int width, int height) {
+        Grid g = grid(z)
+        double boundsWidth = g.xResolution * width
+        double boundsHeight = g.yResolution * height
+        new Bounds(p.x - boundsWidth / 2, p.y - boundsHeight / 2, p.x + boundsWidth / 2, p.y + boundsHeight / 2, this.proj)
+    }
+
     /**
      * Calculate the Bounds for the given Tile
      * @param t The Tile

src/main/groovy/geoscript/layer/TileCursor.groovy

@@ -1,6 +1,7 @@
 package geoscript.layer
 
 import geoscript.geom.Bounds
+import geoscript.geom.Point
 import org.geotools.util.logging.Logging
 import java.util.logging.Logger
 
@@ -221,6 +222,20 @@ class TileCursor<T extends Tile> implements Iterator {
         }
     }
 
+    /**
+     * Create a TileCursor for all Tiles centered on a Point for a given zoom level that fill an image of
+     * a certain width and height
+     * @param layer The TileLayer
+     * @param p The Point (in the TileLayer's Projection)
+     * @param z The zoom level
+     * @param w The image width
+     * @param h The image height
+     * @return A TileCursor
+     */
+    TileCursor(TileLayer layer, Point p, long z, int w, int h) {
+        this(layer, layer.pyramid.bounds(p, z, w, h), z)
+    }
+
     /**
      * Validate number parameters passed into the TileCursor constructor
      * @param num The number value

src/main/groovy/geoscript/layer/TileLayer.groovy

@@ -2,6 +2,7 @@ package geoscript.layer
 
 import geoscript.feature.Field
 import geoscript.geom.Bounds
+import geoscript.geom.Point
 import geoscript.proj.Projection
 import geoscript.workspace.Memory
 import geoscript.workspace.Workspace
@@ -113,6 +114,19 @@ abstract class TileLayer<T extends Tile> implements Closeable {
         new TileCursor(this, b, w, h)
     }
 
+    /**
+     * Get a TileCursor for all Tiles centered on a Point for a given zoom level that fill an image of
+     * a certain width and height
+     * @param p The Point (in the TileLayer's Projection)
+     * @param z The zoom level
+     * @param w The image width
+     * @param h The image height
+     * @return A TileCursor
+     */
+    TileCursor<T> tiles(Point p, long z, int w, int h) {
+        new TileCursor(this, p, z, w, h)
+    }
+
     /**
      * Delete all of the Tiles in the TileCursor
      * @param tiles The TileCursor

src/test/groovy/geoscript/layer/PyramidTestCase.groovy

@@ -1,6 +1,7 @@
 package geoscript.layer
 
 import geoscript.geom.Bounds
+import geoscript.geom.Point
 import geoscript.proj.Projection
 import org.junit.Rule
 import org.junit.Test
@@ -98,6 +99,14 @@ class PyramidTestCase {
         assertEquals(b1, b2)
     }
 
+    @Test
+    void osmBoundsAroundPoint() {
+        Pyramid pyramid = Pyramid.createGlobalMercatorPyramid()
+        pyramid.origin = Pyramid.Origin.TOP_LEFT
+        Bounds bounds = pyramid.bounds(Projection.transform(new Point(-100.81,46.81),"EPSG:4326","EPSG:3857"), 8, 400, 300)
+        assertEquals(new Bounds(-1.1344314741869908E7,5819468.535791107,-1.1099920991869908E7,6002763.848291107, "EPSG:3857"), bounds)
+    }
+
     @Test
     void getTileCoordinates() {
         Pyramid pyramid = Pyramid.createGlobalMercatorPyramid()

src/test/groovy/geoscript/layer/TileCursorTestCase.groovy

@@ -1,8 +1,9 @@
 package geoscript.layer
 
 import geoscript.geom.Bounds
+import geoscript.geom.Point
+import geoscript.proj.Projection
 import org.junit.Test
-
 import static org.junit.Assert.*
 
 /**
@@ -135,6 +136,22 @@ class TileCursorTestCase {
         assertNotNull cursorBounds.proj
     }
 
+    @Test
+    void boundsAroundPoint() {
+        File file = new File(getClass().getClassLoader().getResource("states.mbtiles").toURI())
+        MBTiles layer = new MBTiles(file)
+        TileCursor cursor = new TileCursor(layer, Projection.transform(new Point(-100.81,46.81),"EPSG:4326","EPSG:3857"), 8, 400, 300)
+        assertEquals(8, cursor.z)
+        assertEquals(55, cursor.minX)
+        assertEquals(165, cursor.minY)
+        assertEquals(57, cursor.maxX)
+        assertEquals(166, cursor.maxY)
+        assertEquals(3, cursor.width)
+        assertEquals(2, cursor.height)
+        assertEquals(6, cursor.size)
+        layer.close()
+    }
+
     @Test
     void resetAfterHasNextFalse() {
         File file = new File(getClass().getClassLoader().getResource("states.mbtiles").toURI())

src/test/groovy/geoscript/layer/TileLayerTestCase.groovy

@@ -2,12 +2,15 @@ package geoscript.layer
 
 import geoscript.feature.Feature
 import geoscript.geom.Bounds
+import geoscript.geom.Point
 import geoscript.proj.Projection
 import org.geotools.image.test.ImageAssert
 import org.junit.Rule
 import org.junit.Test
 import org.junit.rules.TemporaryFolder
 
+import javax.imageio.ImageIO
+
 import static junit.framework.Assert.*
 
 /**
@@ -224,6 +227,22 @@ class TileLayerTestCase {
         layer.close()
     }
 
+    @Test
+    void boundsAroundPoint() {
+        File file = new File(getClass().getClassLoader().getResource("states.mbtiles").toURI())
+        MBTiles layer = new MBTiles(file)
+        TileCursor cursor = layer.tiles(Projection.transform(new Point(-100.81,46.81),"EPSG:4326","EPSG:3857"), 8, 400, 300)
+        assertEquals(8, cursor.z)
+        assertEquals(55, cursor.minX)
+        assertEquals(165, cursor.minY)
+        assertEquals(57, cursor.maxX)
+        assertEquals(166, cursor.maxY)
+        assertEquals(3, cursor.width)
+        assertEquals(2, cursor.height)
+        assertEquals(6, cursor.size)
+        layer.close()
+    }
+
     @Test
     void getRaster() {
         File file = new File(getClass().getClassLoader().getResource("states.mbtiles").toURI())
@@ -256,6 +275,22 @@ class TileLayerTestCase {
         layer.close()
     }
 
+    @Test
+    void getRasterAroundPoint() {
+        File file = new File(getClass().getClassLoader().getResource("states.mbtiles").toURI())
+        MBTiles layer = new MBTiles(file)
+        Point point = Projection.transform(new Point(-100.81,46.81),"EPSG:4326","EPSG:3857")
+        Raster raster = layer.getRaster(point, 4, 300, 200)
+        assertNotNull raster
+        ImageAssert.assertEquals(new File(getClass().getClassLoader().getResource("geoscript/layer/tilelayer_raster_point.png").toURI()), raster.image, 100)
+        File out = folder.newFile("raster.png")
+        WorldImage format = new WorldImage(out)
+        format.write(raster)
+        assertTrue out.exists()
+        assertTrue out.length() > 0
+        layer.close()
+    }
+
     @Test
     void getLayer() {
         File file = new File(getClass().getClassLoader().getResource("states.mbtiles").toURI())