Add test

Author: zhongwuzw

shell/platform/darwin/ios/framework/Source/accessibility_bridge_test.mm

@@ -5,11 +5,61 @@
 #import <XCTest/XCTest.h>
 
 #import "flutter/shell/platform/darwin/common/framework/Headers/FlutterMacros.h"
+#import "flutter/shell/platform/darwin/ios/framework/Headers/FlutterPlatformViews.h"
+#import "flutter/shell/platform/darwin/ios/framework/Source/FlutterPlatformViews_Internal.h"
 #import "flutter/shell/platform/darwin/ios/framework/Source/accessibility_bridge.h"
 #import "flutter/shell/platform/darwin/ios/platform_view_ios.h"
 #import "third_party/ocmock/Source/OCMock/OCMock.h"
 
 FLUTTER_ASSERT_NOT_ARC
+@class MockPlatformView;
+MockPlatformView* mockPlatformView = nil;
+
+@interface MockPlatformView : UIView
+@end
+@implementation MockPlatformView
+
+- (void)dealloc {
+  mockPlatformView = nil;
+  [super dealloc];
+}
+
+@end
+
+@interface MockFlutterPlatformView : NSObject <FlutterPlatformView>
+@property(nonatomic, strong) UIView* view;
+@end
+
+@implementation MockFlutterPlatformView
+
+- (instancetype)init {
+  if (self = [super init]) {
+    MockPlatformView* view = [[MockPlatformView new] autorelease];
+    mockPlatformView = view;
+    self.view = view;
+  }
+  return self;
+}
+
+- (void)dealloc {
+  self.view = nil;
+  [super dealloc];
+}
+
+@end
+
+@interface MockFlutterPlatformFactory : NSObject <FlutterPlatformViewFactory>
+@end
+
+@implementation MockFlutterPlatformFactory
+- (NSObject<FlutterPlatformView>*)createWithFrame:(CGRect)frame
+                                   viewIdentifier:(int64_t)viewId
+                                        arguments:(id _Nullable)args {
+  MockFlutterPlatformView* platformView = [[MockFlutterPlatformView new] autorelease];
+  return platformView;
+}
+
+@end
 
 namespace flutter {
 namespace {
@@ -131,4 +181,55 @@ - (void)testUpdateSemanticsOneNode {
   OCMVerifyAll(mockFlutterView);
 }
 
+- (void)testSemanticsDeallocated {
+  @autoreleasepool {
+    flutter::MockDelegate mock_delegate;
+    auto thread_task_runner = CreateNewThread("AccessibilityBridgeTest");
+    flutter::TaskRunners runners(/*label=*/self.name.UTF8String,
+                                 /*platform=*/thread_task_runner,
+                                 /*raster=*/thread_task_runner,
+                                 /*ui=*/thread_task_runner,
+                                 /*io=*/thread_task_runner);
+    auto platform_view = std::make_unique<flutter::PlatformViewIOS>(
+        /*delegate=*/mock_delegate,
+        /*rendering_api=*/flutter::IOSRenderingAPI::kSoftware,
+        /*task_runners=*/runners);
+    id mockFlutterView = OCMClassMock([FlutterView class]);
+    std::string label = "some label";
+
+    flutter::FlutterPlatformViewsController* flutterPlatformViewsController =
+        (flutter::FlutterPlatformViewsController*)(new flutter::FlutterPlatformViewsController());
+    flutterPlatformViewsController->SetFlutterView(mockFlutterView);
+
+    MockFlutterPlatformFactory* factory = [[MockFlutterPlatformFactory new] autorelease];
+    flutterPlatformViewsController->RegisterViewFactory(
+        factory, @"MockFlutterPlatformView",
+        FlutterPlatformViewGestureRecognizersBlockingPolicyEager);
+    FlutterResult result = ^(id result) {
+    };
+    flutterPlatformViewsController->OnMethodCall(
+        [FlutterMethodCall
+            methodCallWithMethodName:@"create"
+                           arguments:@{@"id" : @2, @"viewType" : @"MockFlutterPlatformView"}],
+        result);
+
+    __block auto bridge = std::make_unique<flutter::AccessibilityBridge>(
+        /*view=*/mockFlutterView,
+        /*platform_view=*/platform_view.get(),
+        /*platform_views_controller=*/flutterPlatformViewsController);
+
+    flutter::SemanticsNodeUpdates nodes;
+    flutter::SemanticsNode semantics_node;
+    semantics_node.id = 2;
+    semantics_node.platformViewId = 2;
+    semantics_node.label = label;
+    nodes[kRootNodeId] = semantics_node;
+    flutter::CustomAccessibilityActionUpdates actions;
+    bridge->UpdateSemantics(/*nodes=*/nodes, /*actions=*/actions);
+    flutterPlatformViewsController->Reset();
+    delete flutterPlatformViewsController;
+  }
+  XCTAssertNil(mockPlatformView);
+}
+
 @end