Shift some deps to //flutter/third_party (#50830)

Part of flutter/flutter#67373

Author: zanderso

DEPS

@@ -283,8 +283,8 @@ deps = {
   'src/flutter/third_party/rapidjson':
    Var('flutter_git') + '/third_party/rapidjson' + '@' + 'ef3564c5c8824989393b87df25355baf35ff544b',
 
-  'src/third_party/harfbuzz':
-   Var('flutter_git') + '/third_party/harfbuzz' + '@' + 'b61761f36e93c3f1e36c9bed0755acfa7f4e3d4f',
+  'src/flutter/third_party/harfbuzz':
+   Var('flutter_git') + '/third_party/harfbuzz' + '@' + 'ea8f97c615f0ba17dc25013ef67dbd6bfaaa76f2',
 
   'src/third_party/libcxx':
    Var('llvm_git') + '/llvm-project/libcxx' + '@' + '44079a4cc04cdeffb9cfe8067bfb3c276fb2bab0',
@@ -313,7 +313,7 @@ deps = {
   'src/flutter/third_party/benchmark':
    Var('chromium_git') + '/external/github.com/google/benchmark' + '@' + '431abd149fd76a072f821913c0340137cc755f36',
 
-  'src/third_party/googletest':
+  'src/flutter/third_party/googletest':
    Var('chromium_git') + '/external/github.com/google/googletest' + '@' + '7f036c5563af7d0329f20e8bb42effb04629f0c0',
 
   'src/flutter/third_party/boringssl':
@@ -628,7 +628,7 @@ deps = {
   'src/flutter/third_party/expat':
    Var('chromium_git') + '/external/github.com/libexpat/libexpat.git' + '@' + '654d2de0da85662fcc7644a7acd7c2dd2cfb21f0',
 
-  'src/third_party/freetype2':
+  'src/flutter/third_party/freetype2':
    Var('flutter_git') + '/third_party/freetype2' + '@' + '3bea2761290a1cbe7d8f75c1c5a7ad727f826a66',
 
   'src/flutter/third_party/skia':

build/secondary/flutter/third_party/googletest/BUILD.gn

@@ -0,0 +1,96 @@
+# Copyright 2018 The Fuchsia Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+if (is_fuchsia) {
+  import("//build/fuchsia/sdk.gni")
+}
+
+config("gtest_private_config") {
+  visibility = [ ":*" ]
+  include_dirs = [ "googletest" ]
+}
+
+config("gtest_config") {
+  include_dirs = [ "googletest/include" ]
+}
+
+static_library("gtest") {
+  testonly = true
+  public = [
+    "googletest/include/gtest/gtest-spi.h",
+    "googletest/include/gtest/gtest.h",
+    "googletest/include/gtest/gtest_prod.h",
+  ]
+
+  # Only add the "*-all.cc" files (and no headers) to improve maintainability
+  # from upstream refactoring. The "*-all.cc" files include the respective
+  # source files.
+  sources = [ "googletest/src/gtest-all.cc" ]
+
+  public_configs = [ ":gtest_config" ]
+  configs += [ ":gtest_private_config" ]
+
+  if (is_fuchsia) {
+    if (using_fuchsia_sdk) {
+      deps = [
+        "$fuchsia_sdk_root/pkg:fdio",
+        "$fuchsia_sdk_root/pkg:zx",
+      ]
+    } else {
+      deps = [
+        "//zircon/public/lib/fdio",
+        "//zircon/public/lib/zx",
+      ]
+    }
+  }
+}
+
+# Library that defines the FRIEND_TEST macro.
+source_set("gtest_prod") {
+  testonly = false
+  public = [ "googletest/include/gtest/gtest_prod.h" ]
+  public_configs = [ ":gtest_config" ]
+}
+
+static_library("gtest_main") {
+  testonly = true
+  sources = [ "googletest/src/gtest_main.cc" ]
+  public_deps = [ ":gtest" ]
+}
+
+config("gmock_private_config") {
+  visibility = [ ":*" ]
+  include_dirs = [ "googlemock" ]
+}
+
+config("gmock_config") {
+  include_dirs = [ "googlemock/include" ]
+
+  cflags_cc = [
+    # The MOCK_METHODn() macros do not specify "override", which triggers this
+    # warning in users: "error: 'Method' overrides a member function but is not
+    # marked 'override' [-Werror,-Winconsistent-missing-override]". Suppress
+    # these warnings until https://github.com/google/googletest/issues/533 is
+    # fixed.
+    "-Wno-inconsistent-missing-override",
+  ]
+}
+
+static_library("gmock") {
+  testonly = true
+  public = [ "googlemock/include/gmock/gmock.h" ]
+  sources = [ "googlemock/src/gmock-all.cc" ]
+  public_configs = [ ":gmock_config" ]
+  configs += [ ":gmock_private_config" ]
+  deps = [ ":gtest" ]
+}
+
+static_library("gmock_main") {
+  testonly = true
+  sources = [ "googlemock/src/gmock_main.cc" ]
+  public_deps = [
+    ":gmock",
+    ":gtest",
+  ]
+}

build/secondary/third_party/freetype2/BUILD.gn

@@ -0,0 +1,7 @@
+# Copyright 2013 The Flutter Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+group("freetype2") {
+  public_deps = [ "//flutter/third_party/freetype2" ]
+}