Enabled metal on ios simulator (flutter#17881)

Author: Kavantix

shell/common/switches.h

@@ -97,7 +97,7 @@ DEF_SWITCH(EnableSoftwareRendering,
            "enable-software-rendering",
            "Enable rendering using the Skia software backend. This is useful "
            "when testing Flutter on emulators. By default, Flutter will "
-           "attempt to either use OpenGL or Vulkan.")
+           "attempt to either use OpenGL, Metal, or Vulkan.")
 DEF_SWITCH(SkiaDeterministicRendering,
            "skia-deterministic-rendering",
            "Skips the call to SkGraphics::Init(), thus avoiding swapping out "

shell/gpu/gpu_surface_metal.h

@@ -12,12 +12,13 @@
 #include "flutter/fml/platform/darwin/scoped_nsobject.h"
 #include "flutter/shell/gpu/gpu_surface_delegate.h"
 #include "third_party/skia/include/gpu/GrDirectContext.h"
+#include "third_party/skia/include/gpu/mtl/GrMtlTypes.h"
 
 @class CAMetalLayer;
 
 namespace flutter {
 
-class GPUSurfaceMetal : public Surface {
+class SK_API_AVAILABLE_CA_METAL_LAYER GPUSurfaceMetal : public Surface {
  public:
   GPUSurfaceMetal(GPUSurfaceDelegate* delegate,
                   fml::scoped_nsobject<CAMetalLayer> layer,

shell/platform/darwin/ios/framework/Source/FlutterEngine.mm

@@ -474,6 +474,8 @@ - (BOOL)createShell:(NSString*)entrypoint
   self.initialRoute = initialRoute;
 
   auto settings = [_dartProject.get() settings];
+  FlutterView.forceSoftwareRendering = settings.enable_software_rendering;
+
   auto platformData = [_dartProject.get() defaultPlatformData];
 
   if (libraryURI) {
@@ -513,7 +515,8 @@ - (BOOL)createShell:(NSString*)entrypoint
   flutter::Shell::CreateCallback<flutter::PlatformView> on_create_platform_view =
       [](flutter::Shell& shell) {
         return std::make_unique<flutter::PlatformViewIOS>(
-            shell, flutter::GetRenderingAPIForProcess(), shell.GetTaskRunners());
+            shell, flutter::GetRenderingAPIForProcess(FlutterView.forceSoftwareRendering),
+            shell.GetTaskRunners());
       };
 
   flutter::Shell::CreateCallback<flutter::Rasterizer> on_create_rasterizer =

shell/platform/darwin/ios/framework/Source/FlutterView.h

@@ -21,7 +21,6 @@
                                   asBase64Encoded:(BOOL)base64Encode;
 
 - (flutter::FlutterPlatformViewsController*)platformViewsController;
-
 @end
 
 @interface FlutterView : UIView
@@ -35,6 +34,8 @@
                           opaque:(BOOL)opaque NS_DESIGNATED_INITIALIZER;
 - (std::unique_ptr<flutter::IOSSurface>)createSurface:(std::shared_ptr<flutter::IOSContext>)context;
 
+// Set by FlutterEngine or FlutterViewController to override software rendering.
+@property(class, nonatomic) BOOL forceSoftwareRendering;
 @end
 
 #endif  // SHELL_PLATFORM_IOS_FRAMEWORK_SOURCE_FLUTTER_VIEW_H_

shell/platform/darwin/ios/framework/Source/FlutterView.mm

@@ -68,8 +68,19 @@ - (void)layoutSubviews {
   [super layoutSubviews];
 }
 
+static BOOL _forceSoftwareRendering;
+
++ (BOOL)forceSoftwareRendering {
+  return _forceSoftwareRendering;
+}
+
++ (void)setForceSoftwareRendering:(BOOL)forceSoftwareRendering {
+  _forceSoftwareRendering = forceSoftwareRendering;
+}
+
 + (Class)layerClass {
-  return flutter::GetCoreAnimationLayerClassForRenderingAPI();
+  return flutter::GetCoreAnimationLayerClassForRenderingAPI(
+      flutter::GetRenderingAPIForProcess(FlutterView.forceSoftwareRendering));
 }
 
 - (std::unique_ptr<flutter::IOSSurface>)createSurface:

shell/platform/darwin/ios/framework/Source/FlutterViewController.mm

@@ -157,6 +157,12 @@ - (instancetype)init {
 
 - (void)sharedSetupWithProject:(nullable FlutterDartProject*)project
                   initialRoute:(nullable NSString*)initialRoute {
+  // Need the project to get settings for the view. Initializing it here means
+  // the Engine class won't initialize it later.
+  if (!project) {
+    project = [[[FlutterDartProject alloc] init] autorelease];
+  }
+  FlutterView.forceSoftwareRendering = project.settings.enable_software_rendering;
   auto engine = fml::scoped_nsobject<FlutterEngine>{[[FlutterEngine alloc]
                 initWithName:@"io.flutter"
                      project:project

shell/platform/darwin/ios/ios_surface.mm

@@ -7,6 +7,8 @@
 #import "flutter/shell/platform/darwin/ios/ios_surface_gl.h"
 #import "flutter/shell/platform/darwin/ios/ios_surface_software.h"
 
+#include "flutter/shell/platform/darwin/ios/rendering_api_selection.h"
+
 #if FLUTTER_SHELL_ENABLE_METAL
 #import "flutter/shell/platform/darwin/ios/ios_surface_metal.h"
 #endif  // FLUTTER_SHELL_ENABLE_METAL
@@ -30,13 +32,15 @@
   }
 
 #if FLUTTER_SHELL_ENABLE_METAL
-  if ([layer.get() isKindOfClass:[CAMetalLayer class]]) {
-    return std::make_unique<IOSSurfaceMetal>(
-        fml::scoped_nsobject<CAMetalLayer>(
-            reinterpret_cast<CAMetalLayer*>([layer.get() retain])),  // Metal layer
-        std::move(context),                                          // context
-        platform_views_controller                                    // platform views controller
-    );
+  if (@available(iOS METAL_IOS_VERSION_BASELINE, *)) {
+    if ([layer.get() isKindOfClass:[CAMetalLayer class]]) {
+      return std::make_unique<IOSSurfaceMetal>(
+          fml::scoped_nsobject<CAMetalLayer>(
+              reinterpret_cast<CAMetalLayer*>([layer.get() retain])),  // Metal layer
+          std::move(context),                                          // context
+          platform_views_controller                                    // platform views controller
+      );
+    }
   }
 #endif  // FLUTTER_SHELL_ENABLE_METAL
 

shell/platform/darwin/ios/ios_surface_metal.h

@@ -8,12 +8,14 @@
 #include "flutter/fml/macros.h"
 #include "flutter/shell/gpu/gpu_surface_delegate.h"
 #import "flutter/shell/platform/darwin/ios/ios_surface.h"
+#include "third_party/skia/include/gpu/mtl/GrMtlTypes.h"
 
 @class CAMetalLayer;
 
 namespace flutter {
 
-class IOSSurfaceMetal final : public IOSSurface, public GPUSurfaceDelegate {
+class SK_API_AVAILABLE_CA_METAL_LAYER IOSSurfaceMetal final : public IOSSurface,
+                                                              public GPUSurfaceDelegate {
  public:
   IOSSurfaceMetal(fml::scoped_nsobject<CAMetalLayer> layer,
                   std::shared_ptr<IOSContext> context,

shell/platform/darwin/ios/rendering_api_selection.h

@@ -17,11 +17,23 @@ enum class IOSRenderingAPI {
   kMetal,
 };
 
-IOSRenderingAPI GetRenderingAPIForProcess();
+// Pass force_software to force software rendering. This is only respected on
+// simulators.
+IOSRenderingAPI GetRenderingAPIForProcess(bool force_software);
 
-Class GetCoreAnimationLayerClassForRenderingAPI(
-    IOSRenderingAPI rendering_api = GetRenderingAPIForProcess());
+Class GetCoreAnimationLayerClassForRenderingAPI(IOSRenderingAPI rendering_api);
 
 }  // namespace flutter
 
+// Flutter supports Metal on all devices with Apple A7 SoC or above that have
+// been updated to or past iOS 10.0. The processor was selected as it is the
+// first version at which Metal was supported. The iOS version floor was
+// selected due to the availability of features used by Skia.
+// Support for Metal on simulators was added by Apple in the SDK for iOS 13.
+#if TARGET_OS_SIMULATOR
+#define METAL_IOS_VERSION_BASELINE 13.0
+#else
+#define METAL_IOS_VERSION_BASELINE 10.0
+#endif  // TARGET_OS_SIMULATOR
+
 #endif  // FLUTTER_SHELL_PLATFORM_DARWIN_IOS_RENDERING_API_SELECTION_H_

shell/platform/darwin/ios/rendering_api_selection.mm

@@ -10,37 +10,49 @@
 #if FLUTTER_SHELL_ENABLE_METAL
 #include <Metal/Metal.h>
 #endif  // FLUTTER_SHELL_ENABLE_METAL
+#import <TargetConditionals.h>
 
 #include "flutter/fml/logging.h"
 
 namespace flutter {
 
 #if FLUTTER_SHELL_ENABLE_METAL
 bool ShouldUseMetalRenderer() {
-  // Flutter supports Metal on all devices with Apple A7 SoC or above that have been updated to or
-  // past iOS 10.0. The processor was selected as it is the first version at which Metal was
-  // supported. The iOS version floor was selected due to the availability of features used by Skia.
   bool ios_version_supports_metal = false;
-  if (@available(iOS 10.0, *)) {
+  if (@available(iOS METAL_IOS_VERSION_BASELINE, *)) {
     auto device = MTLCreateSystemDefaultDevice();
     ios_version_supports_metal = [device supportsFeatureSet:MTLFeatureSet_iOS_GPUFamily1_v3];
   }
   return ios_version_supports_metal;
 }
 #endif  // FLUTTER_SHELL_ENABLE_METAL
 
-IOSRenderingAPI GetRenderingAPIForProcess() {
-#if TARGET_IPHONE_SIMULATOR
-  return IOSRenderingAPI::kSoftware;
-#endif  // TARGET_IPHONE_SIMULATOR
+IOSRenderingAPI GetRenderingAPIForProcess(bool force_software) {
+#if TARGET_OS_SIMULATOR
+  if (force_software) {
+    return IOSRenderingAPI::kSoftware;
+  }
+#else
+  if (force_software) {
+    FML_LOG(WARNING) << "The --enable-software-rendering is only supported on Simulator targets "
+                        "and will be ignored.";
+  }
+#endif  // TARGET_OS_SIMULATOR
 
 #if FLUTTER_SHELL_ENABLE_METAL
   static bool should_use_metal = ShouldUseMetalRenderer();
   if (should_use_metal) {
     return IOSRenderingAPI::kMetal;
   }
 #endif  // FLUTTER_SHELL_ENABLE_METAL
+
+  // OpenGL will be emulated using software rendering by Apple on the simulator, so we use the
+  // Skia software rendering since it performs a little better than the emulated OpenGL.
+#if TARGET_OS_SIMULATOR
+  return IOSRenderingAPI::kSoftware;
+#else
   return IOSRenderingAPI::kOpenGLES;
+#endif  // TARGET_OS_SIMULATOR
 }
 
 Class GetCoreAnimationLayerClassForRenderingAPI(IOSRenderingAPI rendering_api) {
@@ -49,10 +61,12 @@ Class GetCoreAnimationLayerClassForRenderingAPI(IOSRenderingAPI rendering_api) {
       return [CALayer class];
     case IOSRenderingAPI::kOpenGLES:
       return [CAEAGLLayer class];
-#if !TARGET_IPHONE_SIMULATOR
     case IOSRenderingAPI::kMetal:
-      return [CAMetalLayer class];
-#endif  // !TARGET_IPHONE_SIMULATOR
+      if (@available(iOS METAL_IOS_VERSION_BASELINE, *)) {
+        return [CAMetalLayer class];
+      }
+      FML_CHECK(false) << "Metal availability should already have been checked";
+      break;
     default:
       break;
   }