Add F# code snippets for ArgumentOutOfRangeException (#7429)

Author: albert-du

samples/snippets/fsharp/VS_Snippets_CLR/ArgumentOutOfRangeException/FS/FS.fsproj

@@ -0,0 +1,12 @@
+<Project Sdk="Microsoft.NET.Sdk">
+
+  <PropertyGroup>
+    <OutputType>Exe</OutputType>
+    <TargetFramework>net6.0</TargetFramework>
+  </PropertyGroup>
+
+  <ItemGroup>
+    <Compile Include="program.fs" />
+  </ItemGroup>
+
+</Project>

samples/snippets/fsharp/VS_Snippets_CLR/ArgumentOutOfRangeException/FS/program.fs

@@ -0,0 +1,20 @@
+// <Snippet1>
+open System
+
+type Guest(fName: string, lName: string, age: int) =
+    let minimumRequiredAge = 21
+
+    do if age < minimumRequiredAge then 
+        raise (ArgumentOutOfRangeException(nameof age, $"All guests must be {minimumRequiredAge}-years-old or older."))
+
+    member _.FirstName = fName
+    member _.LastName = lName
+    member _.GuestInfo() = $"{fName} {lName}, {age}"
+
+try
+    let guest1 = Guest("Ben", "Miller", 17);
+    printfn $"{guest1.GuestInfo()}"
+with
+| :? ArgumentOutOfRangeException as e ->
+    printfn $"Error: {e.Message}"
+// </Snippet1>

samples/snippets/fsharp/VS_Snippets_CLR_System/System.ArgumentOutOfRangeException/fs/BadSearch.fs

@@ -0,0 +1,33 @@
+module BadSearch
+
+// <Snippet6>
+open System
+
+module StringSearcher =
+    let findEquals (s: string) value =
+        s.Equals(value, StringComparison.InvariantCulture)
+
+let list = ResizeArray<string>()
+list.AddRange [ "A"; "B"; "C" ]
+// Get the index of the element whose value is "Z".
+let index = list.FindIndex(StringSearcher.findEquals "Z")
+try 
+    printfn $"Index {index} contains '{list[index]}'"
+with 
+| :? ArgumentOutOfRangeException as e ->
+    printfn $"{e.Message}" 
+
+// The example displays the following output:
+//   Index was out of range. Must be non-negative and less than the size of the collection. (Parameter 'index')
+// </Snippet6>
+
+module Example2 =
+    let test () =
+        let list = new ResizeArray<string>();
+        list.AddRange [ "A"; "B"; "C" ]
+        // <Snippet7>
+        // Get the index of the element whose value is "Z".
+        let index = list.FindIndex(StringSearcher.findEquals "Z")
+        if index >= 0 then
+            printfn $"'Z' is found at index {list[index]}"
+        // </Snippet7>

samples/snippets/fsharp/VS_Snippets_CLR_System/System.ArgumentOutOfRangeException/fs/EmptyString1.fs

@@ -0,0 +1,29 @@
+module EmptyString1
+
+// <Snippet15>
+open System
+
+let getFirstCharacter (s: string) = s[0]
+
+let words = [ "the"; "today"; "tomorrow"; " "; "" ]
+for word in words do
+    printfn $"First character of '{word}': '{getFirstCharacter word}'"
+
+// The example displays the following output:
+//    First character of 'the': 't'
+//    First character of 'today': 't'
+//    First character of 'tomorrow': 't'
+//    First character of ' ': ' '
+//
+//    Unhandled Exception: System.IndexOutOfRangeException: Index was outside the bounds of the array.
+//       at <StartupCode$argumentoutofrangeexception>.$EmptyString1.main@()
+// </Snippet15>
+
+module StringLib =
+   // <Snippet16>
+   let getFirstCharacter (s: string) =
+      if String.IsNullOrEmpty s then
+         '\u0000'
+      else
+         s[0]
+   // </Snippet16>

samples/snippets/fsharp/VS_Snippets_CLR_System/System.ArgumentOutOfRangeException/fs/FindWords1.fs

@@ -0,0 +1,32 @@
+module FindWords1
+
+// <Snippet19>
+
+let findWords (s: string) =
+    let mutable start, end' = 0, 0
+    let delimiters = [| ' '; '.'; ','; ';'; ':'; '('; ')' |]
+    let words = ResizeArray<string>()
+    while end' >= 0 do
+        end' <- s.IndexOfAny(delimiters, start)
+        if end' >= 0 then
+            if end' - start > 0 then
+                words.Add(s.Substring(start, end' - start))
+            start <- end' + 1
+        elif start < s.Length - 1 then
+            words.Add(s.Substring start)
+    words.ToArray()
+
+let sentence = "This is a simple, short sentence."
+printfn $"Words in '{sentence}':"
+for word in findWords sentence do
+    printfn $"   '{word}'"
+
+// The example displays the following output:
+//       Words in 'This is a simple, short sentence.':
+//          'This'
+//          'is'
+//          'a'
+//          'simple'
+//          'short'
+//          'sentence'
+// </Snippet19>

samples/snippets/fsharp/VS_Snippets_CLR_System/System.ArgumentOutOfRangeException/fs/NoElements.fs

@@ -0,0 +1,27 @@
+module NoElements
+
+// <Snippet4>
+open System
+
+
+let list = ResizeArray<string>()
+printfn $"Number of items: {list.Count}"
+try
+    printfn $"The first item: '{list[0]}'"
+with 
+| :? ArgumentOutOfRangeException as e ->
+    printfn $"{e.Message}"
+
+// The example displays the following output:
+//   Number of items: 0
+//   Index was out of range. Must be non-negative and less than the size of the collection. (Parameter 'index')
+// </Snippet4>
+
+module Example2 = 
+    let test () =
+        let list = ResizeArray<string>()
+        printfn $"Number of items: {list.Count}"
+        // <Snippet5>
+        if list.Count > 0 then
+            printfn $"The first item: '{list[0]}'"
+        // </Snippet5>

samples/snippets/fsharp/VS_Snippets_CLR_System/System.ArgumentOutOfRangeException/fs/NoElements2.fs

@@ -0,0 +1,26 @@
+module NoElements2
+
+// <Snippet13>
+let numbers = ResizeArray<int>()
+numbers.AddRange [ 0; 1; 2; 3; 4; 5; 6; 7; 8; 9; 20 ]
+
+let squares = ResizeArray<int>()
+for  ctr = 0 to numbers.Count - 1 do
+    squares[ctr] <- int (float numbers[ctr] ** 2)
+
+// The example displays the following output:
+//    Unhandled Exception: System.ArgumentOutOfRangeException: Index was out of range. Must be non-negative and less than the size of the collection. (Parameter 'index')
+//       at System.ThrowHelper.ThrowArgumentOutOfRangeException(ExceptionArgument argument, ExceptionResource resource)
+//       at <StartupCode$argumentoutofrangeexception>.$NoElements.main@()
+// </Snippet13>
+
+module Correction =
+    let test () =
+        let numbers = ResizeArray<int>()
+        numbers.AddRange [| 0; 1; 2; 3; 4; 5; 6; 7; 8; 9; 20 |]
+        // <Snippet14>
+        let squares = ResizeArray<int>()
+        for ctr = 0 to numbers.Count - 1 do
+            squares.Add(int (float numbers[ctr] ** 2))
+        // </Snippet14>
+   

samples/snippets/fsharp/VS_Snippets_CLR_System/System.ArgumentOutOfRangeException/fs/NoFind1.fs

@@ -0,0 +1,21 @@
+module NoFind1
+
+// <Snippet17>
+let getSecondWord (s: string) =
+    let pos = s.IndexOf " "
+    s.Substring(pos).Trim()
+
+let phrases = [ "ocean blue"; "concerned citizen"; "runOnPhrase" ]
+for phrase in phrases do
+    printfn $"Second word is {getSecondWord phrase}"
+
+// The example displays the following output:
+//    Second word is blue
+//    Second word is citizen
+//
+//    Unhandled Exception: System.ArgumentOutOfRangeException: StartIndex cannot be less than zero. (Parameter 'startIndex')
+//       at System.String.Substring(Int32 startIndex, Int32 length)
+//       at System.String.Substring(Int32 startIndex)
+//       at NoFind1.getSecondWord(String s)
+//       at <StartupCode$argumentoutofrangeexception>.$NoFind1.main@()
+// </Snippet17>

samples/snippets/fsharp/VS_Snippets_CLR_System/System.ArgumentOutOfRangeException/fs/NoFind2.fs

@@ -0,0 +1,22 @@
+module NoFind2
+
+// <Snippet18>
+open System
+
+let getSecondWord (s: string) =
+    let pos = s.IndexOf " "
+    if pos >= 0 then
+        s.Substring(pos).Trim()
+    else 
+        String.Empty
+
+let phrases = [ "ocean blue"; "concerned citizen"; "runOnPhrase" ]
+for phrase in phrases do
+    let word = getSecondWord phrase
+    if not (String.IsNullOrEmpty word) then
+        printfn $"Second word is {word}"
+
+// The example displays the following output:
+//       Second word is blue
+//       Second word is citizen
+// </Snippet18>

samples/snippets/fsharp/VS_Snippets_CLR_System/System.ArgumentOutOfRangeException/fs/OOR1.fs

@@ -0,0 +1,39 @@
+module OOR1
+// <Snippet1>
+open System
+
+let dimension1 = 10
+let dimension2 = -1
+try
+    let arr = Array.CreateInstance(typeof<string>, dimension1, dimension2)
+    printfn "%A" arr
+with 
+| :? ArgumentOutOfRangeException as e ->
+    if not (isNull e.ActualValue) then
+        printfn $"{e.ActualValue} is an invalid value for {e.ParamName}: "
+    printfn $"{e.Message}"
+
+// The example displays the following output:
+//     Non-negative number required. (Parameter 'length2')
+// </Snippet1>
+
+module Example2 =
+    let makeValid () =
+        // <Snippet2>
+        let dimension1 = 10
+        let dimension2 = 10
+        let arr = Array.CreateInstance(typeof<string>, dimension1, dimension2)
+        printfn "%A" arr
+        // </Snippet2>
+
+    let validate () =
+        let dimension1 = 10
+        let dimension2 = 10
+        // <Snippet3>
+        if dimension1 < 0 || dimension2 < 0 then
+            printfn "Unable to create the array."
+            printfn "Specify non-negative values for the two dimensions."
+        else
+            let arr = Array.CreateInstance(typeof<string>, dimension1, dimension2)
+            printfn "%A" arr
+        // </Snippet3>