Add cypher queries to explore code graph schemas

Author: JohT

cypher/Exploration/DEPENDS_ON_relationships.cypher

@@ -0,0 +1,8 @@
+// Get DEPENDS_ON relationships schema 
+
+MATCH (s)-[r:DEPENDS_ON]->(t)
+RETURN labels(s) AS sourceLabels
+      ,labels(t) AS targetLabels
+      ,keys(r)   AS relationshipKeys
+      ,count(*)  AS numberOfNodes
+ORDER BY sourceLabels, targetLabels, relationshipKeys

cypher/Exploration/Explore_ExternalDeclaration.cypher

@@ -0,0 +1,12 @@
+// External declarations split by their module and their contained symbols
+
+MATCH (s:ExternalDeclaration)
+ WITH *
+      ,replace(split(s.globalFqn, '".')[0],'"', '') AS externalDeclarationModule
+      ,split(s.globalFqn, '".')[1] AS externalDeclarationSymbol
+RETURN externalDeclarationModule
+      ,count(DISTINCT externalDeclarationSymbol) AS externalDeclarationSymbols
+      ,collect(externalDeclarationSymbol)[0..4] AS someExternalDeclarationSymbols
+      ,count(*) as numberOfExternalDeclarations
+ORDER BY numberOfExternalDeclarations DESC, externalDeclarationModule ASC
+LIMIT 50

cypher/Exploration/Explore_Module_outgoing_dependencies.cypher

@@ -0,0 +1,17 @@
+// Explore outgoing dependencies of modules
+
+MATCH (source:Module)-[rm:DEPENDS_ON]->(module:ExternalModule)
+OPTIONAL MATCH (module)-[:EXPORTS]->(declaration:ExternalDeclaration)<-[re:DEPENDS_ON]-(source)
+OPTIONAL MATCH (source)-[:DECLARES]->(implementation:Function|Variable)-[ri:DEPENDS_ON]->(module)
+OPTIONAL MATCH (source)-[:DECLARES]->(abstract:Interface|TypeAlias)-[ra:DEPENDS_ON]->(module)
+RETURN source.globalFqn               AS module
+      ,count(DISTINCT abstract)       AS numberOfAbstract
+      ,count(DISTINCT declaration)    AS numberOfExternalDeclarations
+      ,count(DISTINCT implementation) AS numberOfImplementations
+      ,sum(rm.cardinality)            AS sumModuleDependencyWeights
+      ,sum(re.cardinality)            AS sumExternalDeclarationWeights
+      ,sum(ri.cardinality)            AS sumImplementationWeights
+      ,sum(ra.cardinality)            AS sumAbstractWeights
+      //TODO sumWeights should sum up to sumModuleDependencyWeights
+      ,sum(re.cardinality) + sum(ri.cardinality) + sum(ra.cardinality) as sumWeights
+ORDER BY source.globalFqn ASC

cypher/Exploration/Explore_Typescript_modules_overview.cypher

@@ -0,0 +1,15 @@
+// Explore nodes grouped by their module (first part of globalFqn)
+
+ MATCH (n:TS)
+ WHERE n.globalFqn IS NOT NULL
+UNWIND labels(n) AS nodeLabel
+  WITH replace(split(n.globalFqn, '".')[0],'"', '') AS module
+      ,collect(split(n.globalFqn, '".')[1])         AS symbols
+      ,nodeLabel
+      ,count(DISTINCT n) as numberOfNodes
+ WHERE nodeLabel <> 'TS'
+RETURN module
+      ,collect(DISTINCT nodeLabel) AS nodeLabels
+      ,sum(numberOfNodes)          AS numberOfNodes
+      ,collect(symbols[0..4])      AS symbolExamples
+ORDER BY module ASC

cypher/Exploration/Explore_Typescript_modules_per_symboltype.cypher

@@ -0,0 +1,15 @@
+// Explore nodes grouped by their module (first part of globalFqn) and their type of contained symbols
+
+ MATCH (n:TS)
+ WHERE n.globalFqn IS NOT NULL
+UNWIND labels(n) AS nodeLabel
+  WITH replace(split(n.globalFqn, '".')[0],'"', '') AS module
+      ,collect(split(n.globalFqn, '".')[1])         AS symbols
+      ,nodeLabel
+      ,count(DISTINCT n) as numberOfNodes
+ WHERE nodeLabel <> 'TS'
+RETURN module
+      ,collect(DISTINCT nodeLabel) as nodeLabels
+      ,numberOfNodes
+      ,symbols[0..4] AS symbolExamples
+ORDER BY module ASC

cypher/Exploration/Explore_node_properties.cypher

@@ -0,0 +1,11 @@
+// Explore node properties, the labels of their nodes and their count
+
+MATCH (n)
+UNWIND keys(n)   AS nodePropertyName
+UNWIND labels(n) AS nodeLabel
+RETURN nodePropertyName
+      ,collect(DISTINCT nodeLabel)   AS nodeLabels
+      ,count(DISTINCT n)             AS numberOfNodes
+      ,count(DISTINCT n[nodePropertyName])         AS numberOfDistinctValues
+      ,collect(DISTINCT n[nodePropertyName])[0..4] AS exampleValues
+ORDER BY nodePropertyName

cypher/Exploration/Explore_node_relationships.cypher

@@ -0,0 +1,11 @@
+// Get all relationships of one specific node to explore the schema 
+
+MATCH (s:TS:Module)-[r]->(t)
+RETURN labels(s) AS sourceLabels
+      ,keys(s)   AS sourceKeys
+      ,labels(t) AS targetLabels
+      ,keys(t)   AS targetKeys
+      ,type(r)   AS relationshipType
+      ,keys(r)   AS relationshipKeys
+      ,count(*)  AS numberOfNodes
+ORDER BY sourceLabels, targetLabels, relationshipKeys