Make weight setter language dependent

JohT · JohT · commit efde9897bf82 · 2024-03-26T21:30:53.000+01:00
diff --git a/cypher/DependsOn_Relationship_Weights/Add_fine_grained_weights_for_Typescript_module_dependencies.cypher b/cypher/DependsOn_Relationship_Weights/Add_fine_grained_weights_for_Typescript_module_dependencies.cypher
@@ -1,84 +1,76 @@
 // Add weight property for low coupling dependencies to Typescript module DEPENDS_ON relationships
 
- MATCH (source:TS:Module)-[moduleDependency:DEPENDS_ON]->(target:ExternalModule)
 // Get the top level dependency between a Typescript module and the external modules it uses
-  WITH source
-      ,target
-      ,moduleDependency
-      ,count(DISTINCT target)            AS externalModuleCount
-      ,sum(moduleDependency.cardinality) AS externalModuleCardinalities
-OPTIONAL MATCH (source)-[rd:DEPENDS_ON]->(declaration:ExternalDeclaration)<-[:EXPORTS]-(target)
+ MATCH (source:TS:Module)-[moduleDependency:DEPENDS_ON]->(target:ExternalModule)
 // Get optional external (e.g. type) declarations that the external module (target) provides and the source module uses
+OPTIONAL MATCH (source)-[rd:DEPENDS_ON]->(declaration:ExternalDeclaration)<-[:EXPORTS]-(target)
   WITH source
       ,target
       ,moduleDependency
-      ,externalModuleCount
-      ,externalModuleCardinalities
-      ,count(DISTINCT declaration) AS declarationCount
-      ,sum(rd.cardinality)         AS declarationCardinalities
+      ,count(DISTINCT rd)                            AS declarationCount
+      ,sum(rd.cardinality)                           AS declarationCardinalities
       ,collect(DISTINCT declaration.globalFqn)[0..4] AS declarationExamples 
-OPTIONAL MATCH (source)-[:DECLARES]->(abstraction:TypeAlias|Interface)-[ra:DEPENDS_ON]->(target)
 // Get optional low coupling elements (TypeAlias, Interface) that the source module contains and defines (low level) that depend on the external module (target)
+OPTIONAL MATCH (source)-[:DECLARES]->(abstraction:TypeAlias|Interface)-[ra:DEPENDS_ON]->(target)
   WITH source
       ,target
       ,moduleDependency
-      ,externalModuleCount
-      ,externalModuleCardinalities
       ,declarationCount
       ,declarationCardinalities
       ,declarationExamples
-      ,count(DISTINCT abstraction) AS abstractionCount
-      ,sum(ra.cardinality)         AS abstractionCardinalities
+      ,count(DISTINCT ra)                            AS abstractionCount
+      ,sum(ra.cardinality)                           AS abstractionCardinalities
       ,collect(DISTINCT abstraction.globalFqn)[0..4] AS abstractionExamples 
-OPTIONAL MATCH (source)-[:DECLARES]->(implementation:!TypeAlias&!Interface)-[ri:DEPENDS_ON]->(target)
 // Get optional higher coupling elements (Class, Function) that the source module contains and defines (low level) that depend on the external module (target)
+OPTIONAL MATCH (source)-[:DECLARES]->(implementation:!TypeAlias&!Interface)-[ri:DEPENDS_ON]->(target)
   WITH source
       ,target
       ,moduleDependency
-      ,externalModuleCount
-      ,externalModuleCardinalities
       ,declarationCount
       ,declarationCardinalities
       ,declarationExamples
       ,abstractionCount
       ,abstractionCardinalities
       ,abstractionExamples 
-      ,count(DISTINCT implementation) AS implementationCount
-      ,sum(ri.cardinality)            AS implementationCardinalities
+      ,count(DISTINCT ri)                               AS implementationCount
+      ,sum(ri.cardinality)                              AS implementationCardinalities
       ,collect(DISTINCT implementation.globalFqn)[0..4] AS implementationExamples
 // Set additional fine grained relationship properties (weights) to distinguish low and high coupling elements.
 // The "cardinality" property is similar to "weight" property for Java dependencies and comes from the jQAssistant Typescript Plugin.
-// - "weightLowCouplingElements" is the sum of all TypeAlias, Interface and external declaration cardinalities
+// - "lowCouplingElementWeight" is the sum of all TypeAlias, Interface and external declaration cardinalities
 //   and corresponds to the "weightInterfaces" relationship property for Java.
-// - "weight25PercentLowCouplingElements" only takes 25% of the weight for elements that are considered as low coupling
+// - "lowCouplingElement25PercentWeight" only takes 25% of the weight for elements that are considered as low coupling
 //   like Type Declarations and Interfaces and adds the unchanged (100%) weight of "high coupling" elements like Functions and Classes.
-   SET moduleDependency.weightDeclarations        = declarationCardinalities
-      ,moduleDependency.weightAbstractions        = abstractionCardinalities
-      ,moduleDependency.weightImplementations     = implementationCardinalities
-      ,moduleDependency.weightLowCouplingElements = declarationCardinalities + abstractionCardinalities
-      ,moduleDependency.weight25PercentLowCouplingElements = toInteger(implementationCardinalities + round((declarationCardinalities + abstractionCardinalities) * 0.25))
-      ,moduleDependency.weight10PercentLowCouplingElements = toInteger(implementationCardinalities + round((declarationCardinalities + abstractionCardinalities) * 0.10))
+  SET moduleDependency.declarationCount     = declarationCount
+     ,moduleDependency.abstractionCount     = abstractionCount
+     ,moduleDependency.implementationCount  = implementationCount
+     ,moduleDependency.declarationWeight    = declarationCardinalities
+     ,moduleDependency.abstractionWeight    = abstractionCardinalities
+     ,moduleDependency.implementationWeight = implementationCardinalities
+     ,moduleDependency.lowCouplingElementWeight = declarationCardinalities + abstractionCardinalities
+     ,moduleDependency.lowCouplingElement25PercentWeight = toInteger(implementationCardinalities + round((declarationCardinalities + abstractionCardinalities) * 0.25))
+     ,moduleDependency.lowCouplingElement10PercentWeight = toInteger(implementationCardinalities + round((declarationCardinalities + abstractionCardinalities) * 0.10))
 // Aggregate all gathered information for each (grouped by) source module
   WITH source
-      ,source.globalFqn                 AS sourceGlobalName
-      ,source.localFqn                  AS sourceLocalName
-      ,sum(externalModuleCount)         AS externalModuleCount
-      ,sum(declarationCount)            AS declarationCount
-      ,sum(abstractionCount)            AS abstractionCount
-      ,sum(implementationCount)         AS implementationCount
-      ,sum(externalModuleCardinalities) AS externalModuleCardinalities
-      ,sum(declarationCardinalities)    AS declarationCardinalities
-      ,sum(abstractionCardinalities)    AS abstractionCardinalities
-      ,sum(implementationCardinalities) AS implementationCardinalities
+      ,source.globalFqn                  AS sourceGlobalName
+      ,source.localFqn                   AS sourceLocalName
+      ,count(DISTINCT target.globalFqn)  AS externalModuleCount
+      ,sum(moduleDependency.declarationCount)             AS declarationCount
+      ,sum(moduleDependency.abstractionCount)             AS abstractionCount
+      ,sum(moduleDependency.implementationCount)          AS implementationCount
+      ,sum(moduleDependency.cardinality) AS externalModuleCardinalities
+      ,sum(moduleDependency.declarationWeight)     AS declarationCardinalities
+      ,sum(moduleDependency.abstractionWeight)     AS abstractionCardinalities
+      ,sum(moduleDependency.implementationWeight)  AS implementationCardinalities
       ,collect(DISTINCT target.globalFqn)[0..4]                 AS externalModuleExamples
       ,apoc.coll.flatten(collect(declarationExamples))[0..4]    AS declarationExamples
       ,apoc.coll.flatten(collect(abstractionExamples))[0..4]    AS abstractionExamples
       ,apoc.coll.flatten(collect(implementationExamples))[0..4] AS implementationExamples
-   SET source.outgoingDependencies                 = declarationCount + abstractionCount + implementationCount
-      ,source.outgoingDependenciesWeight           = declarationCardinalities + abstractionCardinalities + implementationCardinalities
-      ,source.outgoingDependentImplementations     = implementationCount
-      ,source.outgoingDependentLowCouplingElements = declarationCount + abstractionCount 
-      ,source.outgoingDependentModules             = externalModuleCount
+  SET source.outgoingDependencies                 = declarationCount + abstractionCount + implementationCount
+     ,source.outgoingDependenciesWeight           = declarationCardinalities + abstractionCardinalities + implementationCardinalities
+     ,source.outgoingDependentImplementations     = implementationCount
+     ,source.outgoingDependentLowCouplingElements = declarationCount + abstractionCount 
+     ,source.outgoingDependentModules             = externalModuleCount
 RETURN sourceGlobalName
       ,sourceLocalName
       ,externalModuleCount
diff --git a/cypher/DependsOn_Relationship_Weights/Add_weight10PercentInterfaces_to_Java_Package_DEPENDS_ON_relationships.cypher b/cypher/DependsOn_Relationship_Weights/Add_weight10PercentInterfaces_to_Java_Package_DEPENDS_ON_relationships.cypher
@@ -1,6 +1,6 @@
 // Add weight10PercentInterfaces to Package DEPENDS_ON relationships
 
- MATCH (package:Package)-[r:DEPENDS_ON]->(dependent:Package)
+ MATCH (package:Java:Package)-[r:DEPENDS_ON]->(dependent:Java:Package)
   WITH package, r
       ,toInteger(r.weight - round(r.weightInterfaces * 0.90)) AS weight10PercentInterfaces
    SET r.weight10PercentInterfaces = weight10PercentInterfaces
diff --git a/cypher/DependsOn_Relationship_Weights/Add_weight25PercentInterfaces_to_Java_Package_DEPENDS_ON_relationships.cypher b/cypher/DependsOn_Relationship_Weights/Add_weight25PercentInterfaces_to_Java_Package_DEPENDS_ON_relationships.cypher
@@ -1,6 +1,6 @@
 // Add weight25PercentInterfaces to Package DEPENDS_ON relationships
 
- MATCH (package:Package)-[r:DEPENDS_ON]->(dependent:Package)
+ MATCH (package:Java:Package)-[r:DEPENDS_ON]->(dependent:Java:Package)
   WITH package, r
       ,toInteger(r.weight - round(r.weightInterfaces * 0.75)) AS weight25PercentInterfaces
    SET r.weight25PercentInterfaces = weight25PercentInterfaces
diff --git a/cypher/DependsOn_Relationship_Weights/Add_weight_property_for_Java_Interface_Dependencies_to_Package_DEPENDS_ON_Relationship.cypher b/cypher/DependsOn_Relationship_Weights/Add_weight_property_for_Java_Interface_Dependencies_to_Package_DEPENDS_ON_Relationship.cypher
@@ -1,6 +1,6 @@
 // Add weight property for Interface Dependencies to Package DEPENDS_ON Relationship
 
- MATCH (sourcePackage:Package)-[packageDependency:DEPENDS_ON]->(dependentPackage:Package)
+ MATCH (sourcePackage:Java:Package)-[packageDependency:DEPENDS_ON]->(dependentPackage:Java:Package)
  MATCH (sourcePackage)-[:CONTAINS]->(sourceType:Type)
  OPTIONAL MATCH (sourceType:Type)-[typeDependency:DEPENDS_ON]->(dependentInterface:Interface)<-[:CONTAINS]-(dependentPackage)
  WHERE sourcePackage.fqn <> dependentPackage.fqn
diff --git a/cypher/DependsOn_Relationship_Weights/Add_weight_property_to_Java_Package_DEPENDS_ON_Relationship.cypher b/cypher/DependsOn_Relationship_Weights/Add_weight_property_to_Java_Package_DEPENDS_ON_Relationship.cypher
@@ -1,6 +1,6 @@
 // Add weight property to Package DEPENDS_ON Relationship 
 
- MATCH (sourcePackage:Package)-[:CONTAINS]->(sourceType:Type)-[typeDependency:DEPENDS_ON]->(dependentType:Type)<-[:CONTAINS]-(dependentPackage:Package)
+ MATCH (sourcePackage:Java:Package)-[:CONTAINS]->(sourceType:Type)-[typeDependency:DEPENDS_ON]->(dependentType:Type)<-[:CONTAINS]-(dependentPackage:Java:Package)
  MATCH (sourcePackage)-[packageDependency:DEPENDS_ON]->(dependentPackage)
  WHERE sourcePackage.fqn <> dependentPackage.fqn
   WITH packageDependency
diff --git a/cypher/Exploration/Add_module_property_to_ExternalModule.cypher b/cypher/Exploration/Add_module_property_to_ExternalModule.cypher
@@ -0,0 +1,7 @@
+// Add "module" property to ExternalModule nodes for Typescript
+
+ MATCH (ext:TS:ExternalModule)
+  WITH ext
+      ,reverse(split(reverse(ext.globalFqn), '/')[0]) AS moduleName
+   SET ext.module = moduleName
+RETURN moduleName, ext.globalFqn
diff --git a/cypher/Exploration/Add_name_and_module_properties_to_ExternalDeclaration.cypher b/cypher/Exploration/Add_name_and_module_properties_to_ExternalDeclaration.cypher
@@ -0,0 +1,9 @@
+// Add "name" and "module" properties to ExternalDeclaration nodes for Typescript
+
+ MATCH (ext:TS:ExternalDeclaration)
+  WITH ext
+      ,replace(split(ext.globalFqn, '".')[0],'"', '') AS moduleName
+      ,split(ext.globalFqn, '".')[1]                  AS symbolName
+   SET ext.name   = symbolName
+      ,ext.module = moduleName
+RETURN moduleName, symbolName
diff --git a/cypher/Exploration/Explore_Typescript_projects.cypher b/cypher/Exploration/Explore_Typescript_projects.cypher
@@ -0,0 +1,5 @@
+// Explore Typescript Projects
+
+MATCH (project:TS:Project)-[:HAS_ROOT]->(dir:Directory)-[:CONTAINS]->(module:Module)
+OPTIONAL MATCH (project)<-[:REFERENCED_PROJECTS*]-(top:TS:Project)
+RETURN project, dir, module, top
diff --git a/cypher/Metrics/Set_Outgoing_Typescript_Module_Dependencies.cypher b/cypher/Metrics/Set_Outgoing_Typescript_Module_Dependencies.cypher
@@ -0,0 +1,42 @@
+// Set outgoing Typscript Module dependencies
+
+// Get the top level dependency between a Typescript module and the external modules it uses
+ MATCH (source:TS:Module)-[moduleDependency:DEPENDS_ON]->(target:ExternalModule)
+OPTIONAL MATCH (projectdir:Directory)<-[:HAS_ROOT]-(project:TS:Project)-[:CONTAINS]->(:TS:Module{globalFqn: target.globalFqn})
+// Aggregate all gathered information for each (grouped by) source module
+  WITH source
+      ,source.globalFqn                           AS sourceGlobalName
+      ,source.localFqn                            AS sourceLocalName
+      ,collect(DISTINCT projectdir.absoluteFileName) AS projectNames
+      ,count(DISTINCT target.globalFqn)           AS externalModuleCount
+      ,sum(moduleDependency.declarationCount)     AS declarationCount
+      ,sum(moduleDependency.abstractionCount)     AS abstractionCount
+      ,sum(moduleDependency.implementationCount)  AS implementationCount
+      ,sum(moduleDependency.declarationWeight)    AS declarationCardinalities
+      ,sum(moduleDependency.abstractionWeight)    AS abstractionCardinalities
+      ,sum(moduleDependency.implementationWeight) AS implementationCardinalities
+      ,collect(DISTINCT target.globalFqn)[0..4]   AS externalModuleExamples
+  SET source.outgoingDependencies                 = declarationCount + abstractionCount + implementationCount
+     ,source.outgoingDependenciesWeight           = declarationCardinalities + abstractionCardinalities + implementationCardinalities
+     ,source.outgoingDependentImplementations     = implementationCount
+     ,source.outgoingDependentDeclarations        = declarationCount
+     ,source.outgoingDependentAbstractElements    = abstractionCount
+     ,source.outgoingDependentLowCouplingElements = declarationCount + abstractionCount 
+     ,source.outgoingDependentModules             = externalModuleCount
+     ,source.outgoingDependentPackages            = size(projectNames)
+RETURN sourceGlobalName
+      ,sourceLocalName
+      ,size(projectNames) AS projects
+      ,source.outgoingDependencies
+      ,source.outgoingDependenciesWeight
+      ,source.outgoingDependentImplementations
+      ,source.outgoingDependentDeclarations
+      ,source.outgoingDependentAbstractElements
+      ,source.outgoingDependentLowCouplingElements
+      ,source.outgoingDependentModules 
+      ,declarationCardinalities
+      ,abstractionCardinalities
+      ,implementationCardinalities
+      ,externalModuleExamples
+      ,projectNames
+ORDER BY sourceGlobalName ASC
diff --git a/scripts/prepareAnalysis.sh b/scripts/prepareAnalysis.sh
@@ -31,8 +31,8 @@ source "${SCRIPTS_DIR}/executeQueryFunctions.sh"
 source "${SCRIPTS_DIR}/parseCsvFunctions.sh"
 
 # Local Constants
-PACKAGE_WEIGHTS_CYPHER_DIR="$CYPHER_DIR/Package_Relationship_Weights"
-PACKAGE_METRICS_CYPHER_DIR="$CYPHER_DIR/Metrics"
+DEPENDS_ON_CYPHER_DIR="$CYPHER_DIR/DependsOn_Relationship_Weights"
+METRICS_CYPHER_DIR="$CYPHER_DIR/Metrics"
 EXTERNAL_DEPENDENCIES_CYPHER_DIR="$CYPHER_DIR/External_Dependencies"
 ARTIFACT_DEPENDENCIES_CYPHER_DIR="$CYPHER_DIR/Artifact_Dependencies"
 TYPES_CYPHER_DIR="$CYPHER_DIR/Types"
@@ -52,15 +52,23 @@ execute_cypher "${CYPHER_DIR}/Create_index_for_full_qualified_type_name.cypher"
 # execute_cypher "${CYPHER_DIR}/Create_a_DEPENDS_ON_relationship_for_every_DEPENDS_ON_PACKAGE.cypher"
 # execute_cypher "${CYPHER_DIR}/Create_a_DEPENDS_ON_relationship_for_every_DEPENDS_ON_ARTIFACT.cypher"
 
-# Preparation - Add weights to package DEPENDS_ON relationships 
-execute_cypher_expect_results "${PACKAGE_WEIGHTS_CYPHER_DIR}/Add_weight_property_for_Interface_Dependencies_to_Package_DEPENDS_ON_Relationship.cypher"
-execute_cypher_expect_results "${PACKAGE_WEIGHTS_CYPHER_DIR}/Add_weight_property_to_Package_DEPENDS_ON_Relationship.cypher"
-execute_cypher_expect_results "${PACKAGE_WEIGHTS_CYPHER_DIR}/Add_weight25PercentInterfaces_to_Package_DEPENDS_ON_relationships.cypher" 
-execute_cypher_expect_results "${PACKAGE_WEIGHTS_CYPHER_DIR}/Add_weight10PercentInterfaces_to_Package_DEPENDS_ON_relationships.cypher"
+# Preparation - Add weights to Java Package DEPENDS_ON relationships 
+execute_cypher "${DEPENDS_ON_CYPHER_DIR}/Add_weight_property_for_Java_Interface_Dependencies_to_Package_DEPENDS_ON_Relationship.cypher"
+execute_cypher "${DEPENDS_ON_CYPHER_DIR}/Add_weight_property_to_Java_Package_DEPENDS_ON_Relationship.cypher"
+execute_cypher "${DEPENDS_ON_CYPHER_DIR}/Add_weight25PercentInterfaces_to_Java_Package_DEPENDS_ON_relationships.cypher" 
+execute_cypher "${DEPENDS_ON_CYPHER_DIR}/Add_weight10PercentInterfaces_to_Java_Package_DEPENDS_ON_relationships.cypher"
 
-# Preparation - Add Package node properties "incomingDependencies" and "outgoingDependencies"
-execute_cypher_expect_results "${PACKAGE_METRICS_CYPHER_DIR}/Set_Incoming_Package_Dependencies.cypher"
-execute_cypher_expect_results "${PACKAGE_METRICS_CYPHER_DIR}/Set_Outgoing_Package_Dependencies.cypher"
+# Preparation - Add weights to Typescript Module DEPENDS_ON relationships
+execute_cypher "${DEPENDS_ON_CYPHER_DIR}/Add_fine_grained_weights_for_Typescript_module_dependencies.cypher"
+
+# Preparation - Add Typescript Module node properties "incomingDependencies" and "outgoingDependencies"
+# TODO Implement incoming (and outgoing) dependencies
+#execute_cypher "${METRICS_CYPHER_DIR}/Set_Incoming_Typescript_Module_Dependencies.cypher"
+execute_cypher "${METRICS_CYPHER_DIR}/Set_Outgoing_Typescript_Module_Dependencies.cypher"
+
+# Preparation - Add Java Package node properties "incomingDependencies" and "outgoingDependencies"
+execute_cypher "${METRICS_CYPHER_DIR}/Set_Incoming_Java_Package_Dependencies.cypher"
+execute_cypher "${METRICS_CYPHER_DIR}/Set_Outgoing_Java_Package_Dependencies.cypher"
 
 # Preparation - Label external types and annotations
 #               "external" means that there is no byte code available, not a primitive type and not a java type
@@ -74,11 +82,11 @@ execute_cypher "${EXTERNAL_DEPENDENCIES_CYPHER_DIR}/Remove_external_type_and_ann
 execute_cypher "${EXTERNAL_DEPENDENCIES_CYPHER_DIR}/Label_external_types_and_annotations.cypher"
 
 # Preparation - Add Artifact node properties "incomingDependencies" and "outgoingDependencies"
-execute_cypher_expect_results "${ARTIFACT_DEPENDENCIES_CYPHER_DIR}/Incoming_Artifact_Dependencies.cypher"
-execute_cypher_expect_results "${ARTIFACT_DEPENDENCIES_CYPHER_DIR}/Outgoing_Artifact_Dependencies.cypher"
+execute_cypher "${ARTIFACT_DEPENDENCIES_CYPHER_DIR}/Incoming_Artifact_Dependencies.cypher"
+execute_cypher "${ARTIFACT_DEPENDENCIES_CYPHER_DIR}/Outgoing_Artifact_Dependencies.cypher"
 
-# Preparation - Add Type node properties "incomingDependencies" and "outgoingDependencies"
-execute_cypher_expect_results "${PACKAGE_METRICS_CYPHER_DIR}/Set_Incoming_Type_Dependencies.cypher"
-execute_cypher_expect_results "${PACKAGE_METRICS_CYPHER_DIR}/Set_Outgoing_Type_Dependencies.cypher"
+# Preparation - Add Java Type node properties "incomingDependencies" and "outgoingDependencies"
+execute_cypher "${METRICS_CYPHER_DIR}/Set_Incoming_Java_Type_Dependencies.cypher"
+execute_cypher "${METRICS_CYPHER_DIR}/Set_Outgoing_Java_Type_Dependencies.cypher"
 
 echo "prepareAnalysis: Preparation successful"
