Add general overview with node and relationship types

Author: JohT

cypher/Overview/Node_label_combination_count.cypher

@@ -0,0 +1,22 @@
+// Node count for each label combination. Sums up to the total number of nodes.
+
+ MATCH (allNodes)
+  WITH COUNT(allNodes) AS totalNodeCount
+ MATCH (nodesAndTheirLabels)
+  WITH totalNodeCount
+      ,labels(nodesAndTheirLabels) AS nodeLabels
+      ,nodesAndTheirLabels
+ UNWIND nodeLabels AS nodeLabel
+  WITH totalNodeCount
+      ,nodeLabel
+      ,nodesAndTheirLabels
+ WHERE NOT nodeLabel STARTS WITH 'Mark4'
+  WITH totalNodeCount
+      ,collect(nodeLabel)             AS nodeLabels
+      ,nodesAndTheirLabels
+  WITH totalNodeCount
+      ,nodeLabels
+      ,count(nodesAndTheirLabels)     AS nodesWithThatLabels
+      ,toFloat(count(nodesAndTheirLabels)) / totalNodeCount * 100.0  AS nodesWithThatLabelsPercent
+RETURN nodeLabels, nodesWithThatLabels, nodesWithThatLabelsPercent
+ORDER BY nodesWithThatLabels DESC

cypher/Overview/Node_label_count.cypher

@@ -0,0 +1,16 @@
+// Node count for each label separate. Doesn_t sum up to the number of total labels since one node can have multiple labels.
+
+ MATCH (allNodes)
+  WITH COUNT(allNodes) AS totalNodeCount
+ MATCH (nodesAndTheirLabels)
+  WITH totalNodeCount
+      ,labels(nodesAndTheirLabels) AS nodeLabels
+      ,nodesAndTheirLabels
+ UNWIND nodeLabels AS nodeLabel
+  WITH totalNodeCount
+      ,nodeLabel
+      ,count(nodesAndTheirLabels)                                    AS nodesWithThatLabel
+      ,toFloat(count(nodesAndTheirLabels)) / totalNodeCount * 100.0  AS nodesWithThatLabelPercent
+ WHERE NOT nodeLabel STARTS WITH 'Mark4'
+RETURN nodeLabel, nodesWithThatLabel, nodesWithThatLabelPercent
+ORDER BY nodesWithThatLabel DESC, nodeLabel ASC

cypher/Overview/Node_labels_and_their_relationships.cypher

@@ -0,0 +1,29 @@
+// List node labels and their relationship types, their count and their density.
+
+ MATCH (nodeByLabel)
+  WITH labels(nodeByLabel)  AS nodeLabels
+      ,collect(nodeByLabel) AS nodesWithThatLabels
+      ,count(nodeByLabel)   AS numberOfNodesWithThatLabels
+UNWIND nodesWithThatLabels AS nodeWithThatLabels
+ MATCH (nodeWithThatLabels)-[relation]->(target)
+  WITH nodeLabels                  AS sourceLabels
+      ,numberOfNodesWithThatLabels AS numberOfNodesWithSameLabelsAsSource
+      ,type(relation)              AS relationType
+      ,labels(target)              AS targetLabels
+      ,count(DISTINCT relation)    AS numberOfRelationships
+  WITH sourceLabels
+      ,relationType
+      ,targetLabels
+      ,numberOfRelationships
+      ,numberOfNodesWithSameLabelsAsSource
+      ,count{ MATCH (targetWithLabel) WHERE labels(targetWithLabel) = targetLabels } AS numberOfNodesWithSameLabelsAsTarget
+RETURN sourceLabels
+      ,relationType
+      ,targetLabels
+      ,numberOfRelationships
+      ,numberOfNodesWithSameLabelsAsSource
+      ,numberOfNodesWithSameLabelsAsTarget
+      ,toFloat(numberOfRelationships)
+        / ( numberOfNodesWithSameLabelsAsSource * numberOfNodesWithSameLabelsAsTarget)
+        * 100 AS densityInPercent
+ORDER BY numberOfRelationships DESC

cypher/Overview/Relationship_type_count.cypher

@@ -0,0 +1,15 @@
+// Relationship count for each type separate. Sums up to the total number of relationships (100%).
+
+ MATCH ()-[allRelationships]-()
+  WITH COUNT(DISTINCT allRelationships) AS totalRelationshipCount
+ MATCH ()-[relationshipsAndTheirTypes]-()
+  WITH totalRelationshipCount
+      ,type(relationshipsAndTheirTypes)                AS relationshipType
+      ,count(DISTINCT relationshipsAndTheirTypes)      AS nodesWithThatRelationshipType
+      ,toFloat(
+          count(DISTINCT relationshipsAndTheirTypes)) 
+        / totalRelationshipCount * 100.0               AS nodesWithThatRelationshipTypePercent
+RETURN relationshipType
+      ,nodesWithThatRelationshipType
+      ,nodesWithThatRelationshipTypePercent
+ORDER BY nodesWithThatRelationshipType DESC, relationshipType ASC