Add filtered type projection

Author: JohT

cypher/Dependencies_Projection/Dependencies_3c_Create_Type_Projection.cypher

@@ -0,0 +1,40 @@
+// Create filtered Type node projection without zero-degree nodes, external types, java types or duplicates. Variables: dependencies_projection
+
+ MATCH (internalType:Type)
+ OPTIONAL MATCH (internalType)-[typeDependency:DEPENDS_ON]->(dependentType:Type)
+  WITH internalType
+      ,typeDependency
+      ,dependentType
+      ,(NOT internalType.fqn CONTAINS '.')             AS isPrimitiveInternalType
+      ,(internalType.fqn STARTS WITH 'java.')          AS isJavaInternalType
+      ,exists((internalType)-[:RESOLVES_TO]->(:Type))  AS isDuplicateInternalType
+      ,'ExternalType' in labels(internalType)          AS isExternalInternalType
+      ,exists((internalType)-[:DEPENDS_ON]->(:Type))   AS hasOutgoingDependenciesInternal
+      ,exists((internalType)<-[:DEPENDS_ON]-(:Type))   AS hasIncomingDependenciesInternal
+      ,(NOT dependentType.fqn CONTAINS '.')            AS isPrimitiveTargetType
+      ,(dependentType.fqn STARTS WITH 'java.')         AS isJavaTargetType
+      ,exists((dependentType)-[:RESOLVES_TO]->(:Type)) AS isDuplicateTargetType
+      ,'ExternalType' in labels(dependentType)         AS isExternalTargetType
+      ,exists((dependentType)-[:DEPENDS_ON]->(:Type))  AS hasOutgoingDependenciesTarget
+      ,exists((dependentType)<-[:DEPENDS_ON]-(:Type))  AS hasIncomingDependenciesTarget
+ WHERE NOT isPrimitiveInternalType
+   AND NOT isJavaInternalType 
+   AND NOT isDuplicateInternalType
+   AND NOT isExternalInternalType
+   AND (hasOutgoingDependenciesInternal OR hasIncomingDependenciesInternal)
+   AND NOT isPrimitiveTargetType
+   AND NOT isJavaTargetType 
+   AND NOT isDuplicateTargetType
+   AND NOT isExternalTargetType
+   AND (hasOutgoingDependenciesTarget OR hasIncomingDependenciesTarget)
+  WITH gds.graph.project($dependencies_projection + '-cleaned2', internalType, dependentType, {
+         sourceNodeProperties: internalType {.incomingDependencies, .outgoingDependencies}
+        ,targetNodeProperties: dependentType {.incomingDependencies, .outgoingDependencies}
+        ,relationshipProperties: typeDependency {.weight}
+        ,relationshipType: 'DEPENDS_ON'
+      }
+      ) AS projection
+RETURN projection.graphName         AS graphName
+      ,projection.nodeCount         AS nodeCount
+      ,projection.relationshipCount AS relationshipCount
+      ,projection.projectMillis     AS projectMillis