Enrich Graph for Typescript with multiple projects and packages

Author: JohT

cypher/Typescript_Enrichment/Add_name_to_property_on_projects.cypher

@@ -0,0 +1,7 @@
+// Set name property on Typescript project nodes
+
+ MATCH (project:TS:Project)-[:HAS_ROOT]->(root:Directory)
+  WITH  project
+       ,reverse(split(reverse(root.absoluteFileName), '/')[0]) AS projectName
+   SET  project.name = projectName
+RETURN count(*) AS numberOfNamesProjects

cypher/Typescript_Enrichment/Add_name_to_property_on_scan_nodes.cypher

@@ -0,0 +1,7 @@
+// Set name property on Typescript scan nodes
+
+ MATCH (typescriptScan:TS:Scan)
+  WITH  typescriptScan
+       ,replace(reverse(split(reverse(typescriptScan.fileName), '/')[0]), '.json', '') AS scanName
+   SET  typescriptScan.name = scanName
+RETURN count(*) AS numberOfNamesScans

cypher/Typescript_Enrichment/Link_projects_to_npm_packages.cypher

@@ -0,0 +1,32 @@
+// Link Typescript projects to npm packages
+
+MATCH (npmPackage:NPM:Package)
+ WITH  npmPackage
+// Remove the first ("/npm-package-json/")" and the last part ("/package.json")
+// of the file name to get the actual relative path to the directory 
+// that contains the package.json file
+      ,replace(
+            replace(npmPackage.fileName, '/' + split(npmPackage.fileName, '/')[1], '')
+          , '/package.json'
+          , ''
+          ) AS relativeNpmPackageDirectory
+ MATCH (project:TS:Project)-[:HAS_ROOT]->(projectRoot:Directory)
+ WHERE projectRoot.absoluteFileName ENDS WITH relativeNpmPackageDirectory
+  WITH npmPackage
+      ,relativeNpmPackageDirectory
+      ,collect(DISTINCT project) AS projects
+      ,collect(DISTINCT projectRoot) AS projectRoots
+// Assure that the found connection is unique and not ambiguous 
+ WHERE size(projects)     = 1
+   AND size(projectRoots) = 1
+ UNWIND projects AS project
+// Create a HAS_NPM_PACKAGE relationship between the Typescript project and the npm package
+ MERGE (project)-[:HAS_NPM_PACKAGE]->(npmPackage)
+// Set the "relativeFileDirectory" on the npm package to the relative directory 
+// that contains the package.json file 
+   SET npmPackage.relativeFileDirectory = relativeNpmPackageDirectory
+ RETURN count(*) AS numberOfCreatedNpmPackageRelationships
+// Detailed results for debugging
+//RETURN npmPackage.fileName              AS npmPackageFileName
+//      ,projectRoots[0].absoluteFileName AS projectRootDirectory
+//      ,relativeNpmPackageDirectory

scripts/prepareAnalysis.sh

@@ -54,11 +54,18 @@ execute_cypher "${CYPHER_DIR}/Create_Typescript_index_for_full_qualified_name.cy
 # Preparation - Enrich Graph for Typescript by adding "module" and "name" properties
 execute_cypher "${TYPESCRIPT_CYPHER_DIR}/Add_module_properties.cypher"
 
+# Preparation - Enrich Graph for Typescript by adding a name properties
+execute_cypher "${TYPESCRIPT_CYPHER_DIR}/Add_name_to_property_on_projects.cypher"
+execute_cypher "${TYPESCRIPT_CYPHER_DIR}/Add_name_to_property_on_scan_nodes.cypher"
+
 # Preparation - Enrich Graph for Typescript by adding relationships between Modules with the same globalFqn
 execute_cypher "${TYPESCRIPT_CYPHER_DIR}/Add_RESOLVES_TO_relationship_for_matching_modules.cypher"
 execute_cypher "${TYPESCRIPT_CYPHER_DIR}/Add_RESOLVES_TO_relationship_for_matching_declarations.cypher"
 execute_cypher "${TYPESCRIPT_CYPHER_DIR}/Add_DEPENDS_ON_relationship_to_resolved_modules.cypher"
 
+# Preparation - Enrich Graph for Typescript by adding relationships between corresponding TS:Project and NPM:Package nodes
+execute_cypher "${TYPESCRIPT_CYPHER_DIR}/Link_projects_to_npm_packages.cypher"
+
 # Preparation - Add weights to Java Package DEPENDS_ON relationships 
 execute_cypher_summarized "${DEPENDS_ON_CYPHER_DIR}/Add_weight_property_for_Java_Interface_Dependencies_to_Package_DEPENDS_ON_Relationship.cypher"
 execute_cypher_summarized "${DEPENDS_ON_CYPHER_DIR}/Add_weight_property_to_Java_Package_DEPENDS_ON_Relationship.cypher"