Add file distance to DEPENDS_ON relationships

Author: JohT

cypher/Internal_Dependencies/Set_file_distance_as_shortest_contains_path_for_dependencies.cypher

@@ -0,0 +1,21 @@
+// Set file distance for dependencies as the shortest path of CONTAINS relationships (intuitively the fewest number of change directory commands needed)
+
+   MATCH (source:File)-[dependency:DEPENDS_ON]->(target:File)
+   MATCH changeDirectoryPath = shortestPath((source)-[:CONTAINS*1..15]-(target))
+   WHERE ALL ( file IN nodes(changeDirectoryPath) WHERE "File" IN labels(file) )
+OPTIONAL MATCH (source)<-[:CONTAINS]-(commonDirectory:Directory)-[:CONTAINS]->(target)
+    WITH CASE commonDirectory
+           WHEN IS NOT NULL THEN 0
+           ELSE length(changeDirectoryPath)
+         END                  AS fileDistanceAsFewestChangeDirectoryCommands
+        ,dependency
+        ,source
+        ,target
+    SET dependency.fileDistanceAsFewestChangeDirectoryCommands
+                  =fileDistanceAsFewestChangeDirectoryCommands
+ RETURN fileDistanceAsFewestChangeDirectoryCommands
+       ,count(*)               AS numberOfDependencies
+       ,count(DISTINCT source) AS numberOfDependencyUsers
+       ,count(DISTINCT target) AS numberOfDependencyProviders
+       ,collect(source.fileName + ' uses ' + target.fileName)[0..4] AS examples
+ ORDER BY fileDistanceAsFewestChangeDirectoryCommands

cypher/Internal_Dependencies/Shortest_directory_path_for_dependent_modules_for_Typescript.cypher

@@ -0,0 +1,31 @@
+// Find shortest path regarding file location (contains relationships) between dependent modules (highest incoming dependencies first)
+
+MATCH (sourceModule:TS:Module)<-[dependency:DEPENDS_ON]-(targetModule:TS:Module)
+WHERE sourceModule <> targetModule
+ WITH sourceModule
+     ,count(DISTINCT targetModule)     AS incomingDependencies
+     ,sum(dependency.cardinality)      AS incomingDependencyCardinality
+     ,avg(dependency.declarationCount) AS incomingDependencyAverageDeclarationUsageCount
+     ,collect(DISTINCT targetModule)   AS targetModules
+UNWIND targetModules AS targetModule
+MATCH (sourceModule)<-[dependency:DEPENDS_ON]-(targetModule)
+MATCH changeDirectoryPath = shortestPath((sourceModule)-[:CONTAINS*1..15]-(targetModule))
+WHERE ALL ( n IN nodes(changeDirectoryPath) WHERE "File" IN labels(n) )
+OPTIONAL MATCH (sourceModule)<-[:CONTAINS]-(commonDirectory:Directory)-[:CONTAINS]->(targetModule)
+WHERE commonDirectory IS NULL // remove line to also include modules in the same directory
+RETURN sourceModule.fileName                  AS sourceModuleName
+      ,labels(sourceModule)[0..4]
+      ,incomingDependencies
+      ,incomingDependencyCardinality
+      ,incomingDependencyAverageDeclarationUsageCount
+      ,targetModule.fileName              AS targetModuleName
+      ,dependency.cardinality             AS dependencyCardinality
+      ,dependency.declarationCount        AS usedDeclarations
+      ,CASE commonDirectory
+          WHEN IS NOT NULL THEN 0
+          ELSE length(changeDirectoryPath)
+       END AS shortestChangeDirectoryDistance
+      //,nodes(changeDirectoryPath)                AS shortestChangeDirectoryPath
+      //,sourceModule, targetModule, changeDirectoryPath
+ORDER BY shortestChangeDirectoryDistance DESC, sourceModule.incomingDependencies ASC 
+LIMIT 40