List type communities that span multiple packages

Author: JohT

cypher/Community_Detection/Type_communities_that_span_the_most_packages.cypher

@@ -0,0 +1,19 @@
+// Communities that span the most packages
+
+ MATCH (a:Artifact)-[:CONTAINS]->(p:Package)-[:CONTAINS]->(t:Type)
+  WITH replace(last(split(a.fileName, '/')), '.jar', '') AS artifactName
+      ,t.communityLeidenId                               AS communityId  
+      ,collect(DISTINCT p.fqn)                           AS packageNames
+      ,count(DISTINCT p.fqn)                             AS packageCount
+      ,collect(DISTINCT t.fqn)                           AS typeNames
+      ,count(DISTINCT t.fqn)                             AS typeCount
+ WHERE communityId IS NOT NULL
+RETURN artifactName
+      ,communityId
+      ,packageCount
+      ,typeCount
+      ,packageNames
+      ,typeNames
+ORDER BY packageCount DESCENDING
+        ,typeCount    DESCENDING
+        ,communityId  ASCENDING

cypher/Community_Detection/Type_communities_that_span_the_most_packages_with_type_statistics.cypher

@@ -0,0 +1,39 @@
+// Communities that span the most packages with type statistics
+
+ MATCH (a:Artifact)-[:CONTAINS]->(p:Package)-[:CONTAINS]->(t:Type)
+  WITH replace(last(split(a.fileName, '/')), '.jar', '') AS artifactName
+      ,t.communityLeidenId                               AS communityId
+      ,p.fqn                                             AS packageName
+      ,collect(DISTINCT p.fqn)                           AS packageNames
+      ,count(DISTINCT p.fqn)                             AS packageCount
+      ,collect(DISTINCT t.fqn)                           AS typeNames
+      ,count(DISTINCT t.fqn)                             AS typeCount
+ORDER BY typeCount ASCENDING
+ WHERE communityId IS NOT NULL
+  WITH artifactName
+      ,communityId
+      ,collect(DISTINCT packageName) AS packageNames
+      ,count(DISTINCT packageName)   AS packageCount
+      // The object structure of "packageCommunityTypes" only works in the browser.
+      // It is only meant to be a helper to see how the communities and their packages are distributed in detail.
+      //,collect(DISTINCT {package: packageName, numberOfTypes:typeCount}) AS packageCommunityTypes
+      ,sum(typeCount)                AS sumTypeCount
+      ,min(typeCount)                AS minTypeCount
+      ,max(typeCount)                AS maxTypeCount
+      ,avg(typeCount)                AS avgTypeCount
+      ,stDev(typeCount)              AS stdTypeCount
+      ,percentileDisc(typeCount, 0.5) AS per5TypeCount
+RETURN artifactName
+      ,communityId
+      ,packageCount
+      ,sumTypeCount
+      ,minTypeCount
+      ,maxTypeCount
+      ,avgTypeCount
+      ,stdTypeCount
+      ,per5TypeCount
+      //,packageCommunityTypes
+      ,packageNames
+ORDER BY packageCount DESCENDING
+        ,sumTypeCount DESCENDING
+        ,communityId  ASCENDING

cypher/Community_Detection/Type_communities_with_few_members_in_foreign_packages.cypher

@@ -0,0 +1,34 @@
+// Type communities with few members in foreign packages
+
+ MATCH (t:Type)
+  WITH t.communityLeidenId   AS communityId
+      ,count(DISTINCT t.fqn) AS numberOfTypesInCommunity
+ WHERE communityId           IS NOT NULL
+ MATCH (a:Artifact)-[:CONTAINS]->(p:Package)-[:CONTAINS]->(communityType:Type)
+ MATCH (p)-[:CONTAINS]->(packageType:Type)
+ WHERE communityType.communityLeidenId = communityId
+   AND packageType.communityLeidenId IS NOT NULL
+  WITH replace(last(split(a.fileName, '/')), '.jar', '') AS artifactName
+      ,p.fqn                           AS packageName
+      ,numberOfTypesInCommunity
+      ,count(DISTINCT packageType.fqn) AS numberOfTypesInPackage
+      ,collect(communityType)          AS packageTypes
+UNWIND packageTypes                    AS packageType
+  WITH artifactName
+      ,packageName
+      ,packageType.communityLeidenId   AS communityId
+      ,numberOfTypesInPackage
+      ,numberOfTypesInCommunity
+      ,count(DISTINCT packageType.fqn) AS numberOfTypes
+ WHERE numberOfTypes < numberOfTypesInCommunity
+   AND numberOfTypes < numberOfTypesInPackage
+RETURN artifactName
+      ,packageName
+      ,communityId
+      ,numberOfTypesInPackage
+      ,numberOfTypesInCommunity
+      ,numberOfTypes
+ORDER BY numberOfTypes            ASCENDING
+        ,numberOfTypesInCommunity DESCENDING
+        ,numberOfTypesInPackage   DESCENDING
+        ,packageName              ASCENDING

scripts/reports/CommunityCsv.sh

@@ -389,5 +389,7 @@ detectCommunities "${TYPE_PROJECTION}" "${TYPE_NODE}" "${TYPE_WEIGHT}" "${TYPE_G
 
 # Type Community Detection - Special CSV Queries after update
 execute_cypher "${CYPHER_DIR}/Community_Detection/Which_type_community_spans_several_artifacts_and_how_are_the_types_distributed.cypher" > "${FULL_REPORT_DIRECTORY}/Type_Communities_Leiden_That_Span_Multiple_Artifacts.csv"
+execute_cypher "${CYPHER_DIR}/Community_Detection/Type_communities_with_few_members_in_foreign_packages.cypher" > "${FULL_REPORT_DIRECTORY}/Type_communities_with_few_members_in_foreign_packages.csv"
+execute_cypher "${CYPHER_DIR}/Community_Detection/Type_communities_that_span_the_most_packages_with_type_statistics.cypher" > "${FULL_REPORT_DIRECTORY}/Type_communities_that_span_the_most_packages_with_type_statistics.csv"
 
 echo "communityCsv: $(date +'%Y-%m-%dT%H:%M:%S%z') Successfully finished"