Detect and mark Typescript test modules

Author: JohT

cypher/Typescript_Enrichment/Mark_test_modules.cypher

@@ -0,0 +1,36 @@
+// Add "Test" label for modules that contain tests and test-related implementations
+
+MATCH (m:Module)
+ WITH m
+     ,(m.globalFqn contains '/__tests__/') OR        
+      (m.globalFqn contains '/test/')      OR
+      (m.globalFqn contains '/tests/')                  AS isInTestFolder
+     ,(m.globalFqn contains '/__mocks__/') OR        
+      (m.globalFqn contains '/mock/')      OR      
+      (m.globalFqn contains '/mocks/')                  AS isInMockFolder
+     ,(m.globalFqn ENDS WITH '.test.' + m.extension) OR
+      (m.globalFqn ENDS WITH '/test.' + m.extension) OR
+      (m.globalFqn ENDS WITH 'Test.'  + m.extension)    AS isTestExtension
+     ,(m.globalFqn ENDS WITH '.spec.' + m.extension) OR
+      (m.globalFqn ENDS WITH '/spec.' + m.extension) OR
+      (m.globalFqn ENDS WITH 'Spec.'  + m.extension)    AS isSpecificationExtension
+    //,(m.globalFqn contains 'test')                    AS isTestMentioned // for debugging
+  WITH *
+      ,(isTestExtension OR isSpecificationExtension) AS isTest
+      ,isInMockFolder                                AS isMock
+      ,(isInTestFolder AND NOT isInMockFolder AND NOT isTestExtension AND NOT isSpecificationExtension) AS isTestRelated
+  WITH *
+      ,CASE WHEN isTest        THEN [1] ELSE [] END AS nonEmptyIfTest
+      ,CASE WHEN isMock        THEN [1] ELSE [] END AS nonEmptyIfMock
+      ,CASE WHEN isTestRelated THEN [1] ELSE [] END AS nonEmptyIfTestRelated
+// Set labels "Test", "Mock" or "TestRelated" and the property "testMarkerInteger" (default=0) to filter projections.
+// Numeric properties are required by projections using Neo4j's graph data science library.
+    SET m.testMarkerInteger = 0
+FOREACH (x in nonEmptyIfTest        | SET m:Test,        m.testMarkerInteger = 1)
+FOREACH (x in nonEmptyIfMock        | SET m:Mock,        m.testMarkerInteger = 2)
+FOREACH (x in nonEmptyIfTestRelated | SET m:TestRelated, m.testMarkerInteger = 3)
+RETURN isTest, isMock, isTestRelated
+      ,isInTestFolder, isInMockFolder, isTestExtension, isSpecificationExtension
+    //,isTestMentioned // for debugging
+     ,count(DISTINCT m.globalFqn)          AS numberOfModules
+     ,collect(DISTINCT m.globalFqn)[0..4]  AS examples 

scripts/prepareAnalysis.sh

@@ -55,6 +55,7 @@ execute_cypher "${CYPHER_DIR}/Create_Typescript_index_for_name.cypher"
 # Preparation - Enrich Graph for Typescript by adding "module" and "name" properties
 execute_cypher "${TYPESCRIPT_CYPHER_DIR}/Index_module_name.cypher"
 execute_cypher "${TYPESCRIPT_CYPHER_DIR}/Add_module_properties.cypher"
+execute_cypher "${TYPESCRIPT_CYPHER_DIR}/Mark_test_modules.cypher"
 
 # Preparation - Enrich Graph for Typescript by adding a name properties
 execute_cypher "${TYPESCRIPT_CYPHER_DIR}/Add_name_to_property_on_projects.cypher"