Merge pull request #51 from JohT/feature/parametrize-topology-sort

Parametrize Topological Sort

Author: JohT

cypher/Topological_Sort/Topological_Sort_List.cypher

@@ -0,0 +1,22 @@
+// Topological Sort to list the properties topologicalSortIndex (e.g. build order) and maxDistanceFromSource (build level) for each code unit node.
+// Needs graph-data-science plugin version >= 2.5.0
+
+CALL gds.dag.topologicalSort.stream(
+ $dependencies_projection + '-without-empty', {
+    computeMaxDistanceFromSource: true
+}) YIELD nodeId, maxDistanceFromSource
+   WITH nodeId
+       ,gds.util.asNode(nodeId)          AS codeUnit
+       ,toInteger(maxDistanceFromSource) AS maxDistanceFromSource
+    SET codeUnit.maxDistanceFromSource = maxDistanceFromSource
+   WITH collect(nodeId)                  AS sortedNodeIds
+       ,collect({codeUnit: codeUnit, maxDistanceFromSource: maxDistanceFromSource}) AS topologicalSortedCodeUnits
+       ,max(maxDistanceFromSource)       AS overallMaxDistance
+FOREACH (i IN range(0, SIZE(sortedNodeIds)-1) | 
+    SET gds.util.asNode(sortedNodeIds[i]).topologicalSortIndex = i)
+   WITH topologicalSortedCodeUnits
+       ,overallMaxDistance
+ UNWIND topologicalSortedCodeUnits       AS sorted
+ RETURN coalesce(sorted.codeUnit.fqn, sorted.codeUnit.fileName, sorted.codeUnit.name) AS codeUnitName
+       ,sorted.codeUnit.maxDistanceFromSource                                         AS maxDistanceFromSource
+       ,overallMaxDistance                                                            AS overalNumberOfBuildLevels

cypher/Topological_Sort/Topological_Sort_Query.cypher

@@ -0,0 +1,18 @@
+// Topological Sort to query the properties topologicalSortIndex (e.g. build order) and maxDistanceFromSource (build level) for each code unit node in topologicalSortIndex order.
+// Needs graph-data-science plugin version >= 2.5.0
+
+MATCH (codeUnit)
+ WHERE codeUnit.maxDistanceFromSource IS NOT NULL
+   AND codeUnit.topologicalSortIndex  IS NOT NULL
+   AND $dependencies_projection_node  IN LABELS(codeUnit) 
+  WITH collect(codeUnit)                   AS codeUnits
+      ,max(codeUnit.maxDistanceFromSource) AS overallMaxDistanceFromSource
+UNWIND codeUnits AS codeUnit
+RETURN coalesce(codeUnit.fqn, codeUnit.fileName, codeUnit.name)                          AS codeUnitName
+      ,coalesce(replace(last(split(codeUnit.fileName, '/')), '.jar', ''), codeUnit.name) AS shortName
+      ,codeUnit.topologicalSortIndex                                                     AS topologicalSortIndex
+      ,codeUnit.maxDistanceFromSource                                                    AS maxDistanceFromSource
+      ,overallMaxDistanceFromSource
+      ,codeUnit.incomingDependencies                                                     AS incomingDependencies
+      ,codeUnit.outgoingDependencies                                                     AS outgoingDependencies
+ORDER BY codeUnit.topologicalSortIndex

cypher/Topological_Sort/Topological_Sort_Write.cypher

@@ -0,0 +1,17 @@
+// Topological Sort to write the properties topologicalSortIndex (e.g. build order) and maxDistanceFromSource (build level) into the graph.
+// Needs graph-data-science plugin version >= 2.5.0
+
+CALL gds.dag.topologicalSort.stream(
+ $dependencies_projection + '-without-empty', {
+    computeMaxDistanceFromSource: true
+}) YIELD nodeId, maxDistanceFromSource
+   WITH nodeId
+       ,gds.util.asNode(nodeId)           AS codeUnit
+       ,toInteger(maxDistanceFromSource)  AS maxDistanceFromSource
+    SET codeUnit.maxDistanceFromSource = maxDistanceFromSource
+   WITH collect(nodeId)                   AS sortedNodeIds
+       ,collect(codeUnit)                 AS sortedArtifacts
+       ,max(maxDistanceFromSource)        AS overallMaxDistance
+FOREACH (i IN range(0, SIZE(sortedArtifacts)-1) | 
+    SET gds.util.asNode(sortedNodeIds[i]).topologicalSortIndex = i)
+ RETURN size(sortedArtifacts) AS numberOfArtifacts, overallMaxDistance